Created
March 1, 2021 23:10
-
-
Save MattRix/ea330747c59c1e7d367a4330ad5466e6 to your computer and use it in GitHub Desktop.
Worley cellular noise for HLSL (and Unity), translated from from Stefan Gustavson's GLSL version
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
// Cellular noise ("Worley noise") in 2D in GLSL. | |
// Copyright (c) Stefan Gustavson 2011-04-19. All rights reserved. | |
// This code is released under the conditions of the MIT license. | |
// See LICENSE file for details. | |
// https://github.com/stegu/webgl-noise | |
// Modulo 289 without a division (only multiplications) | |
float3 mod289(float3 x) { | |
return x - floor(x * (1.0 / 289.0)) * 289.0; | |
} | |
float2 mod289(float2 x) { | |
return x - floor(x * (1.0 / 289.0)) * 289.0; | |
} | |
// Modulo 7 without a division | |
float3 mod7(float3 x) { | |
return x - floor(x * (1.0 / 7.0)) * 7.0; | |
} | |
// Permutation polynomial: (34x^2 + x) mod 289 | |
float3 permute(float3 x) { | |
return mod289((34.0 * x + 1.0) * x); | |
} | |
// Cellular noise, returning F1 and F2 in a float2. | |
// Standard 3x3 search window for good F1 and F2 values | |
float2 cellular(float2 P) { | |
#define K 0.142857142857 // 1/7 | |
#define Ko 0.428571428571 // 3/7 | |
#define jitter 1.0 // Less gives more regular pattern | |
float2 Pi = mod289(floor(P)); | |
float2 Pf = frac(P); | |
float3 oi = float3(-1.0, 0.0, 1.0); | |
float3 of = float3(-0.5, 0.5, 1.5); | |
float3 px = permute(Pi.x + oi); | |
float3 p = permute(px.x + Pi.y + oi); // p11, p12, p13 | |
float3 ox = frac(p*K) - Ko; | |
float3 oy = mod7(floor(p*K))*K - Ko; | |
float3 dx = Pf.x + 0.5 + jitter*ox; | |
float3 dy = Pf.y - of + jitter*oy; | |
float3 d1 = dx * dx + dy * dy; // d11, d12 and d13, squared | |
p = permute(px.y + Pi.y + oi); // p21, p22, p23 | |
ox = frac(p*K) - Ko; | |
oy = mod7(floor(p*K))*K - Ko; | |
dx = Pf.x - 0.5 + jitter*ox; | |
dy = Pf.y - of + jitter*oy; | |
float3 d2 = dx * dx + dy * dy; // d21, d22 and d23, squared | |
p = permute(px.z + Pi.y + oi); // p31, p32, p33 | |
ox = frac(p*K) - Ko; | |
oy = mod7(floor(p*K))*K - Ko; | |
dx = Pf.x - 1.5 + jitter*ox; | |
dy = Pf.y - of + jitter*oy; | |
float3 d3 = dx * dx + dy * dy; // d31, d32 and d33, squared | |
// Sort out the two smallest distances (F1, F2) | |
float3 d1a = min(d1, d2); | |
d2 = max(d1, d2); // Swap to keep candidates for F2 | |
d2 = min(d2, d3); // neither F1 nor F2 are now in d3 | |
d1 = min(d1a, d2); // F1 is now in d1 | |
d2 = max(d1a, d2); // Swap to keep candidates for F2 | |
d1.xy = (d1.x < d1.y) ? d1.xy : d1.yx; // Swap if smaller | |
d1.xz = (d1.x < d1.z) ? d1.xz : d1.zx; // F1 is in d1.x | |
d1.yz = min(d1.yz, d2.yz); // F2 is now not in d2.yz | |
d1.y = min(d1.y, d1.z); // nor in d1.z | |
d1.y = min(d1.y, d2.x); // F2 is in d1.y, we're done. | |
return sqrt(d1.xy); | |
} |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment