Nix FHS env for OpenWrt

shell.nix

{ pkgs ? import <nixpkgs> {} }:

let
  fixWrapper = pkgs.runCommand "fix-wrapper" {} ''
    mkdir -p $out/bin
    for i in ${pkgs.gcc.cc}/bin/*-gnu-gcc*; do
      ln -s ${pkgs.gcc}/bin/gcc $out/bin/$(basename "$i")
    done
    for i in ${pkgs.gcc.cc}/bin/*-gnu-{g++,c++}*; do
      ln -s ${pkgs.gcc}/bin/g++ $out/bin/$(basename "$i")
    done
  '';

  fhs = pkgs.buildFHSUserEnv {
    name = "openwrt-env";
    targetPkgs = pkgs: with pkgs;
      [ git
        perl
        gnumake
        gcc
        unzip
        utillinux
        python2
        patch
        wget
        file
        subversion
        which
        pkgconfig
        openssl
        fixWrapper
        systemd
        binutils

        ncurses
        zlib
        zlib.static
        glibc.static
      ];
    multiPkgs = null;
    extraOutputsToInstall = [ "dev" ];
    profile = ''
      export hardeningDisable=all
    '';
  };
in fhs.env

Build is failing with python 2, after switching to python 3 it's working again, maybe you can adjust? :)

This file is maintained here now: https://github.com/nix-community/nix-environments/blob/master/envs/openwrt/shell.nix
Please make a PR if necessary.

Thanks for pointing out, I got across from the WIki where this Gist was still referenced. As I've updated the page before, I changed the reference to the link above. Will also make the PR there 👍