Godot Log AutoLoad. Helper methods to prefix network status in message.

log.gd

# Log AutoLoad
extends Node

const nil = StringName("<NIL>")

func print(message: Variant, m2: Variant = nil, m3: Variant = nil, m4: Variant = nil, m5: Variant = nil, m6: Variant = nil) -> void:
	print(build_message(message, m2, m3, m4, m5, m6))

func prints(message: Variant, m2: Variant = nil, m3: Variant = nil, m4: Variant = nil, m5: Variant = nil, m6: Variant = nil) -> void:
	print(build_message(message, m2, m3, m4, m5, m6, " "))
	
func printt(message: Variant, m2: Variant = nil, m3: Variant = nil, m4: Variant = nil, m5: Variant = nil, m6: Variant = nil) -> void:
	print(build_message(message, m2, m3, m4, m5, m6, "\t"))

func printerr(message: Variant, m2: Variant = nil, m3: Variant = nil, m4: Variant = nil, m5: Variant = nil, m6: Variant = nil) -> void:
	printerr(build_message(message, m2, m3, m4, m5, m6))

func push_error(message: Variant, m2: Variant = nil, m3: Variant = nil, m4: Variant = nil, m5: Variant = nil, m6: Variant = nil) -> void:
	push_error(build_message(message, m2, m3, m4, m5, m6))

func push_warning(message: Variant, m2: Variant = nil, m3: Variant = nil, m4: Variant = nil, m5: Variant = nil, m6: Variant = nil) -> void:
	push_warning(build_message(message, m2, m3, m4, m5, m6))

func build_message(message: Variant, m2: Variant = nil, m3: Variant = nil, m4: Variant = nil, m5: Variant = nil, m6: Variant = nil, separator: Variant = null) -> String:
	var text: String = ""
	for msg in [message, m2, m3, m4, m5, m6]:
		if is_nil(msg):
			continue
		
		if separator && text.length():
			text += separator
		text += str(msg)
	
	return message_prefix() + text

func message_prefix() -> String:
	if !is_multiplayer_connected() || multiplayer.multiplayer_peer is OfflineMultiplayerPeer:
		return ""
	
	var prefix := "["
	if multiplayer.is_server():
		prefix += "SERVER"
	else:
		prefix += "CLIENT %s" % multiplayer.multiplayer_peer.get_unique_id()
	prefix += "] "
	
	return prefix
	
func is_multiplayer_connected() -> bool:
	return multiplayer.multiplayer_peer && multiplayer.multiplayer_peer.get_connection_status() == MultiplayerPeer.CONNECTION_CONNECTED

func is_nil(object: Variant) -> bool:
	return typeof(object) == typeof(nil) && object == nil