Test using Prismatic Schema generated users with distinct email/username

distinct_users.clj

(defn- distinct-users []
  (let [step (fn step [users usernames emails]
               (lazy-seq
                 ((fn [[u :as users] usernames emails] ; first user, usernames, emails
                    (when-let [s (seq users)]
                      (if (or (contains? usernames (:username u))
                              (contains? emails (:email u)))
                        (recur (rest s) usernames emails)
                        (cons u (step (rest s)
                                      (conj usernames (:username u))
                                      (conj emails (:email u)))))))
                  users usernames emails)))]
    (step (repeatedly (partial generate NewUser)) #{} #{})))

(deftest test-user-list
  (with-rollback-transaction [t-conn db/conn]
    (let [users (doall (map user/create! (take 100 (distinct-users))))
          user-page (user/get-users)]
      (is (= 100 (count users)) "user list should be created")
      (is (not (nil? user-page)) "user page should exist")
      (is (= 30 (count user-page)) "default user page should have 30 results"))))