432 PurelyFunctional.tv Newsletter

00 Atbash Cipher.md

Atbash Cipher

The Atbash Cipher is simple: replace every letter with its "mirror" in the alphabet. A is replaced by Z. B is replaced by Y. Etc. Write a function to calculate it.

Examples

(atbash "") ;=> ""
(atbash "hello") ;=> "svool"
(atbash "Clojure") ;=> "Xolqfiv"
(atbash "Yo!") ;=> "Bl!"

Please maintain capitalization and non-alphabetic characters.

Thanks to this site for the problem idea, where it is rated Very Hard in Python. The problem has been modified.

Please submit your solutions as comments on this gist.

To subscribe: https://purelyfunctional.tv/newsletter/

(defn mirror-x [first last x]
     (char (- (int last) (- (int x) (int first)))))

(defn mirror-char [x]
  (cond (re-matches #"[a-z]" (str x)) (mirror-x \a \z x)
        (re-matches #"[A-Z]" (str x)) (mirror-x \A \Z x)
        :else x))

(defn atbash [xs]
  (->> (map mirror-char xs)
       (clojure.string/join "")))

(defn atbash [s]
 (let [alphabet "abcdefghijklmnopqrstuvwxyz"
       alphabet-uc (str/upper-case alphabet)
       cipher (merge (zipmap alphabet (reverse alphabet))
                     (zipmap alphabet-uc (reverse alphabet-uc)))]
   (->> (map (fn [c] (cipher c c)) s)
        (apply str))))

(require '[clojure.string :as str])

(let [alpha "abcdefghijklmnopqrstuvwxyz"
      cipher (apply merge (map #(zipmap % (str/reverse %)) [alpha (str/upper-case alpha)]))]
  (defn atbash [s]
    (str/escape s cipher)))

(defn atbash [s]
  (let [f (fn [b v] [(char (+ b v)) (char (- (+ b 25) v))])
        mf (fn [ff b] (map #(f b %) (range 26)))
        mm (into {} (concat (mf f (int \a)) (mf f (int \A))))]
    (clojure.string/escape s mm)))

(defn atbash [s]
  (let [a-z (map char (range (int \a) (inc (int \z))))
        A-Z (map char (range (int \A) (inc (int \Z))))
        alphabet-keys (concat a-z A-Z)
        alphabet-values (reverse (concat A-Z a-z))
        atbash-mapping (zipmap alphabet-keys alphabet-values)]
    (->> s (map (fn [x] (get atbash-mapping x x))) (apply str)))

(def alphabet "ABCDEFGHIJKLMNOPQRSTUVWXYZ")
(def uppercaseAlphabet (seq alphabet))
(def lowercaseAlphabet (map #(Character/toLowerCase %) alphabet))
(def dictionary
  (merge
    (zipmap uppercaseAlphabet (reverse uppercaseAlphabet))
    (zipmap lowercaseAlphabet (reverse lowercaseAlphabet))))


(defn atbash [s]
  (if (empty? s)
    ""
    (apply str (map #(get dictionary % %) s))))

(require '[clojure.string :as str])

(let [a (int \a), z (int \z), A (int \A), Z (int \Z)
      flip #(let [i (int %)]
             (cond (<= a i z) (char (- z (- i a)))
                   (<= A i Z) (char (- Z (- i A)))
                   :else %))]
  (defn atbash [s]
    (str/escape s flip)))

(defn char-range [from to]
  (map char (range (int from) (inc (int to)))))

(defn mirror-char [char-range]
  (zipmap char-range (reverse char-range)))

(def lowercase-letters (char-range \a \z))

(def uppercase-letters (char-range \A \Z))

(def mirror-letters (merge (mirror-char lowercase-letters) (mirror-char uppercase-letters)))

(defn atbash [s]
  (->> s (map #(get mirror-letters % %)) (apply str)))

(def en-alphabet "abcdefghijklmnopqrstuvwxyz")

(defn atbash-mk-translation-table [alphabet]
  (->> alphabet
       (map-indexed (fn [i el]
                      [el (nth alphabet (- (dec (count alphabet)) i))]))
       (into {})))

(def translation-table
  (merge (atbash-mk-translation-table en-alphabet)
         (atbash-mk-translation-table (clojure.string/upper-case en-alphabet))))

(defn encode [ch]
  (get translation-table ch ch))

(defn atbash [s]
  (if (empty? s)
    ""
    (->> s
         (map encode)
         (clojure.string/join))))

(defn char-range [from to] (map char (range (int from) (+ (int to) 1))))
(defn mirror-part [xs] (zipmap xs (reverse xs)))
(def mirror (merge (mirror-part (char-range \A \Z)) (mirror-part (char-range \a \z))))

(defn atbash [s] (apply str (replace mirror s)))

(defn atbash [s]
   (let [A-Z (map char (range 65  91))
         a-z (map char (range 97 123))
         conversions (merge (zipmap A-Z (reverse A-Z))
                            (zipmap a-z (reverse a-z)))]
     (->> s
          (map #(get conversions % %))
          (clojure.string/join ""))))

• Edited for off by one error for ascii code point of Z.

(def mirror (let [lks "abcdefghijklmnopqrstuvwxyz", 
                  uks (clojure.string/upper-case lks)
                  lvs (reverse lks), 
                  uvs (reverse uks)]
              (-> (zipmap lks lvs)
                  (merge (zipmap uks uvs)))))

(defn atbash [msg]
  (->> msg
       (map #(get mirror % %))
       (apply str)))