Terraria Sprite Extractor

Extractor.boo

namespace WindowsGame2

import System.IO
import Microsoft.Xna.Framework

public class Extractor(Game):
	private graphics as GraphicsDeviceManager
	private basePath as string
	private outPath  as string
	
	def constructor(basePath as string, outPath as string):
		graphics = GraphicsDeviceManager(self)
		self.basePath = basePath
		self.outPath  = outPath
		super.Content.RootDirectory = basePath
	
	override def LoadContent():
		for file as string in Directory.GetFiles(Path.Combine(basePath, 'Images')):
			print('Converting and saving ' + file)
			
			if not Directory.Exists(outPath):
				Directory.CreateDirectory(outPath)
			
			filePath = Path.Combine(outPath, FileInfo(file).Name.Replace('xnb', 'png'))
			if File.Exists(filePath):
				File.Delete(filePath)
			OFS = FileStream(filePath, FileMode.CreateNew, FileAccess.Write)
			
			sourceImage = super.Content.Load[of Graphics.Texture2D](file.Replace('.xnb', ''))
			
			sourceImage.SaveAsPng(OFS, sourceImage.Width, sourceImage.Height)
			OFS.Flush()
			OFS.Close()
		
		System.Windows.Forms.MessageBox.Show('Done!')
		self.Exit()

def Main(args as (string)):
	if args.Length > 1:
		outPath = args[1]
	else:
		outPath = Path.Combine(Directory.GetCurrentDirectory(), "Terraria Sprite Dump")
	extractor = Extractor(args[0], outPath)
	extractor.Run()