風船デモ ( balloons demo ) | MSX-BASIC https://msxjpn.jimdofree.com/%E3%83%97%E3%83%AD%E3%82%B0%E3%83%A9%E3%83%A0/%E9%A2%A8%E8%88%B9%E3%83%87%E3%83%A2/

BALLDEMO.BAS

' balloons demo | MSX-BASIC
' Copyright (c) 2012-2025 Keiichi Shiga (BALLOON | FU-SEN)
' The MIT License (MIT) - https://mit.balloon.net.eu.org/#2012-2025
100 COLOR ,1,1:SCREEN 1,1
110 KEY OFF:WIDTH 30
120 T=RND(-TIME):DEFINT A-Z:B=0
130 DIM X(31),Y(31),C(31),M(31)
140 LOCATE 1,2:PRINT "MSX-BASIC DEMO"
150 H$=CHR$(14)+CHR$(29)
160 H$=H$+CHR$(31)+CHR$(31)
170 H$=H$+CHR$(14)+CHR$(8)
180 H$=H$+CHR$(16)+CHR$(224)
190 SPRITE$(0)=H$
200 FOR I=0 TO 31
210 X(I)=RND(1)*272
220 Y(I)=RND(1)*208
230 C(I)=RND(1)*15+1
240 M(I)=RND(1)*8+1
250 NEXT I
260 FOR I=0 TO 31
270 FOR J=0 TO 31
280 PUT SPRITE J,(X(J)-16,Y(J)-16),C(J),0
290 ON M(J) GOSUB 370,370,410,380,380,380,410,370
300 ON M(J) GOSUB 410,390,390,390,410,400,400,400
310 NEXT J
320 M(I)=RND(1)*8+1
330 IF I MOD 15<>14 GOTO 350
340 B=(B+1)MOD 15:COLOR ,B+1
350 NEXT I
360 GOTO 260
370 Y(J)=(Y(J)+4)MOD 208:RETURN
380 Y(J)=(Y(J)+204)MOD 208:RETURN
390 X(J)=(X(J)+268)MOD 272:RETURN
400 X(J)=(X(J)+4)MOD 272:RETURN
410 RETURN