my version of @luolong's solution to Rosetta Code balanced brackets

balancedBrackets.ceylon

shared void balancedBrackets() {
    value nextRandom = random();
    for (length in 1..10) {
        value text = generate(nextRandom, length);
        print("``text.padTrailing(20)`` - ``if (balanced(text)) then "OK" else "NOT OK"``");
    }
}

Boolean balanced(String input)
        => !input
            .map((ch) => switch (ch) case('[') 1 case (']') -1 else 0)
            .scan(0)(plus)
            .any(Integer.negative);

String generate(Integer() nextRandom, Integer length) 
        => let (jumbled =
            "[]".repeat(length)
                .map((ch) => nextRandom() % length -> ch)
                .sort(increasingKey)
                .map(Entry.item))
        String(jumbled);

Integer random(variable Integer seed 
        = system.nanoseconds + system.milliseconds)() {
    seed = seed.xor(seed.rightLogicalShift(12));
    seed = seed.xor(seed.leftLogicalShift(25));
    seed = seed.xor(seed.rightLogicalShift(27));
    return seed * 2685821657736338717;
}

hmmh..
Do I understand this correctly, that declaring input argument seed as variable in method declaration will cause the random() method to become stateful?