ColdFusion UDF to validate if an email address' MX record exists. (Spammers tend to generate random domain strings when submitting comment spam.)

isEmailDomainValid.cfm

<!--- NOTE: This technique is not 100% accurate because some DNS servers don't allow MX queries or may be slow to respond,
but this will identify addresses that are potentially bad or suspicious. --->
<cfscript>
function isEmailDomainValid(email){
	var local.email = arguments.email;
	var local.DNSServer = '8.8.8.8'; /* Google DNS */
	var local.timeout = 2000;
	var local.attempts = 1;
	var local.valid = true;
	var local.emailDomain = trim(listlast(local.email,'@'));
	var local.DNSRequest = '';
	var local.DNSResponse = '';
	var local.DNSService = '';
	if (arraylen(arguments) GT 1 and len(trim(arguments[2]))) {
		local.DNSServer = arguments[2];
	}
	if (arraylen(arguments) GT 2 and val(trim(arguments[3]))) {
		local.timeout = val(arguments[3]);
	}
	if (arraylen(arguments) GT 3 and val(trim(arguments[4]))) {
		local.attempts = val(arguments[4]);
	}
	if (NOT isvalid('email', arguments.email)){
		var local.valid = false;
	}
	if (local.valid){
		local.DNSService = CreateObject('java', 'java.util.Hashtable');
		local.DNSService.put('java.naming.factory.initial', 'com.sun.jndi.dns.DnsContextFactory');
		local.DNSService.put('java.naming.provider.url', 'dns://#local.DNSServer#');
		local.DNSService.put('com.sun.jndi.dns.timeout.initial', local.timeout);
		local.DNSService.put('com.sun.jndi.dns.timeout.retries', local.attempts);
		local.DNSRequest = CreateObject('java', 'javax.naming.directory.InitialDirContext');
		local.DNSRequest.init(local.DNSService);
		try {
			local.DNSResponse = local.DNSRequest.getAttributes(local.emailDomain, ['MX']).get('MX').getAll().next().ToString();
		} catch (any e){
			local.valid = false;
		}
	}
	return local.valid;
}
</cfscript>


<cfoutput>
<cfsavecontent variable="Emails">test@#CGI.Server_Name#
test@gmail.com
test@gmal.com
test@fake-domain-name.com
test@hotmail.com
test@hotmial.com
test@comcast.com
test@coomcast.com
test@sbcglobel.com
test@yahoo.com
test@yahooo.com
test@yahoo.co
test@aol
test@aol.co
test@aol.cm
test@hormail.com
ttest@coomcast.net
test@invalid_email</cfsavecontent>

<style type="text/css">
li.no {color:##f30;}
li.yes {color:##3c0;}
</style>

<h2>Validate Email Address MX Records</h2>
<ol>
<cfloop array="#ListToArray(Emails,chr(10))#" index="thisEmail">
	<cfset Start = GetTickCount()><cfset Status = isEmailDomainValid(trim(thisEmail))><cfset TheTime = GetTickCount()-Start>
	<li class="#lcase(yesnoformat(Status))#">#trim(ThisEmail)# = #Status# (#numberformat(TheTime)#ms)</li>
</cfloop>
</ol>
</cfoutput>