Wahlomat Daten Sachsen Anhalt 2021

01-load.cypher

create index on :Partei(name);
create index on :These(name);
create constraint if not exists on (p:Partei) assert p.id is unique;
create constraint if not exists on (t:These) assert t.id is unique;

load csv with headers from 
"https://gist.github.com/jexp/189e9d7a47095ff96ff522fe350f0d36/raw/fa2f356514ec981067856ad7a5f6dfb017122c8d/wom-sa-2021.csv" 
as row

merge  (p:Partei {id:toInteger(row.`Partei: Nr.`)}) on create set p.text = row.`Partei: Name`, p.name = row.`Partei: Kurzbezeichnung`
merge (t:These {id:toInteger(row.`These: Nr.`)}) on create set t.name = row.`These: Titel`, t.text = row.`These: These`

merge (p)-[pos:POSITION]->(t) on create set pos.text = row.`Position: Begründung`,
pos.weight = case row.`Position: Position` when "stimme nicht zu" then 0.0 when "stimme zu" then 1.0 when "neutral" then 0.5 end

return count(*);

02-explore.cypher

// top 5 parties, same positions
MATCH (p:Partei)-[r:POSITION]->(t) where p.id <= 5 and t.id <10 and r.weight = 1 RETURN *;

// similarity

match (p1:Partei)-[r1:POSITION]->(t:These)<-[r2:POSITION]-(p2:Partei) where id(p1)>id(p2)
return p1.name,p2.name, sum(abs(r1.weight-r2.weight)) as sim order by sim asc;

03-data-science.cypher

// projection: partei-similar(weight)-partei

call gds.graph.create.cypher("parteien", "MATCH (p:Partei) RETURN id(p) as id", 
"match (p1:Partei)-[r1:POSITION]->(t:These)<-[r2:POSITION]-(p2:Partei) 
 where id(p1)>id(p2) 
 return id(p1) as source,id(p2) as target, (30.0-sum(abs(r1.weight-r2.weight)))/30.0 as weight");
 
 
match (p1:Partei)-[r1:POSITION]->(t:These)<-[r2:POSITION]-(p2:Partei) where id(p1)>id(p2) 
with p1,p2, (29.0-sum(abs(r1.weight-r2.weight)))/29.0 as weight
merge (p1)-[s:SIMILAR]-(p2)
set s.weight = weight;

call gds.louvain.write("parteien",
                {relationshipWeightProperty:'weight', writeProperty:'cluster'})

// undirected graph for embeddings
call gds.graph.create("p4",{Partei:{properties:"cluster"},These:{}},{POSITION:{orientation:"UNDIRECTED",properties:"weight"}});

// CALL gds.graph.removeNodeProperties('p4', ['embedding']);
call gds.fastRP.mutate("p4",{relationshipWeightProperty:"weight", mutateProperty:"embedding", embeddingDimension:128});

// good embeddings
call gds.beta.knn.stream("p4",{nodeLabels:['Partei'],topK:3, nodeWeightProperty:'embedding'})
yield node1, node2, similarity where node1 > node2
return gds.util.asNode(node1).name as n1,gds.util.asNode(node2).name as n2, similarity order by similarity desc;

match ()-[p:POSITION]->() where p.weight is null delete p;


call gds.graph.create("p2",{Partei:{properties:"cluster"},These:{}},{POSITION:{orientation:"NATURAL",properties:"weight"}});

// call gds.fastRP.mutate("p2",{relationshipWeightProperty:"weight", mutateProperty:"embedding", embeddingDimension:128});

// embeddings not great
// call gds.beta.node2vec.mutate("p2",{relationshipWeightProperty:"weight", mutateProperty:"embedding", embeddingDimension:128, walkLength:40, inOutFactor:2.0});

call gds.beta.knn.stream("p4",{nodeLabels:['Partei'],topK:3, nodeWeightProperty:'embedding'})
yield node1, node2, similarity where node1 > node2
return gds.util.asNode(node1).name as n1,gds.util.asNode(node2).name as n2, similarity order by similarity desc;

// todo link prediction, node classification

CALL gds.alpha.ml.nodeClassification.train("p4",{modelName:"classify",featureProperties:["embedding"],targetProperty:"cluster", nodeLabels:["Partei"],
 holdoutFraction: 0.2,
  validationFolds: 5,
  metrics: [ 'F1_WEIGHTED' ],
  params: [
    {penalty: 0.0625},
    {penalty: 0.5},
    {penalty: 1.0},
    {penalty: 4.0}
  ]})
  
  
CALL gds.alpha.ml.nodeClassification.predict.stream('p4', {
  nodeLabels: ['Partei'],
  modelName: 'classify',
  includePredictedProbabilities: true
}) YIELD nodeId, predictedClass, predictedProbabilities
RETURN gds.util.asNode(nodeId).name AS party, gds.util.asNode(nodeId).cluster AS cluster, predictedClass, predictedProbabilities;


// link prediction, only keep PRO-stance links

call gds.beta.graph.create.subgraph("p3","p2","*","r.weight=1.0")

// test relationships
CALL gds.alpha.ml.splitRelationships.mutate('p3', {
  relationshipTypes: ['POSITION'],
  remainingRelationshipType: 'POS_REMAINING',
  holdoutRelationshipType: 'POS_TESTGRAPH',
  holdoutFraction: 0.2,
  negativeSamplingRatio: 1.33,
  randomSeed: 1984
});

// train relationships
CALL gds.alpha.ml.splitRelationships.mutate('p3', {
  relationshipTypes: ['POS_REMAINING'],
  remainingRelationshipType: 'POS_IGNORED_FOR_TRAINING',
  holdoutRelationshipType: 'POS_TRAINGRAPH',
  holdoutFraction: 0.2,
  negativeSamplingRatio: 1.33,
  randomSeed: 1984
}) YIELD relationshipsWritten;

CALL gds.alpha.ml.linkPrediction.train('p3', {
  trainRelationshipType: 'POS_TRAINGRAPH',
  testRelationshipType: 'POS_TESTGRAPH',
  modelName: 'link-pred',
  featureProperties: [],
  validationFolds: 5,
  negativeClassWeight: 1.0 / 1.33,
  randomSeed: 2,
  concurrency: 1,
  params: [
    {penalty: 0.5, maxEpochs: 1000},
    {penalty: 1.0, maxEpochs: 1000},
    {penalty: 0.0, maxEpochs: 1000}
  ]
}) YIELD modelInfo
RETURN
  { maxEpochs: modelInfo.bestParameters.maxEpochs, penalty: modelInfo.bestParameters.penalty } AS winningModel,
  modelInfo.metrics.AUCPR.outerTrain AS trainGraphScore,
  modelInfo.metrics.AUCPR.test AS testGraphScore;
 
 // doesn't really work
 
CALL gds.alpha.ml.linkPrediction.predict.stream('p3', {
  relationshipTypes: ['POSITION'],
  modelName: 'link-pred',
  topN: 5,
  threshold: 0.45
}) YIELD node1, node2, probability
MATCH (p), (t) WHERE id(p) = node1 AND id(t) = node2
OPTIONAL MATCH (p)-[pos:POSITION]-(t)
RETURN
  p.name AS partei,
  t.name AS these,
  pos.weight as existing,
  probability;

wom-sa-2021.csv

Daten von https://www.bpb.de/politik/wahlen/wahl-o-mat/332469/download

danke 🙏

import data on https://sandbox.neo4j.com -> blank sandbox