nodejs_0_10.nix

pkgs:
	with pkgs;

	let
		version = "0.10.42";

		deps = {
			inherit http-parser;
			# inherit openssl;
			cares = c-ares;
		};

		sharedConfigureFlags = name: [
			"--shared-${name}"
			"--shared-${name}-includes=${builtins.getAttr name deps}/include"
			"--shared-${name}-libpath=${builtins.getAttr name deps}/lib"
		];

		inherit (stdenv.lib) concatMap optional optionals maintainers licenses platforms;
	in stdenv.mkDerivation {
		name = "nodejs-${version}";

		src = fetchurl {
			url = "http://nodejs.org/dist/v${version}/node-v${version}.tar.gz";
			sha256 = "01g19mq8b3b828f59x7bv79973w5sw4133ll1dxml37qk0vdbhgb";
		};

		configureFlags = (concatMap sharedConfigureFlags (builtins.attrNames deps)) ++ [
			"--shared-zlib"
			"--shared-zlib-includes=${zlib.dev}/include"
			"--shared-zlib-libpath=${zlib}/lib"
		];

		buildInputs = [ python which utillinux gcc5 zlib ];
		setupHook = ./setup-hook.sh;

		enableParallelBuilding = true;

		passthru.interpreterName = "nodejs-0.10";

		meta = {
			description = "Event-driven I/O framework for the V8 JavaScript engine";
			homepage = http://nodejs.org;
			license = licenses.mit;
			platforms = platforms.linux;
		};
	}

shell.nix

{ pkgs ? import <nixpkgs> {} }:
	with pkgs;

	let
		nodejs_0_10 = import ./nix-shell/nodejs_0_10.nix pkgs;
		manatee = import ./nix-shell/manatee.nix pkgs;
	in stdenv.mkDerivation rec {
		name = "lamassu-machine-development-environment";

		buildInputs = [
			nodejs_0_10
			manatee
			ruby
			libjpeg
			gcc5
		];

		LD_LIBRARY_PATH = stdenv.lib.makeLibraryPath buildInputs;
	}