Solution for Lab 6 Exercise 2

Temperatures.hs

-- | Solution for Lab 6 Exercise 2

module Temperatures where

import Control.Applicative
import Control.Arrow
import Data.Char
import Text.Printf

type Row = [Double]

data Result = Result
    { resultMin :: Double
    , resultMax :: Double
    , resultMean :: Double
    }

main :: IO ()
main = interact (regurgitate . digest . consume)

consume :: String -> [Row]
consume = map (map (read . stripSpaces) . wordsOn (== ',')) . lines

digest :: [Row] -> ([Result], Double)
digest = map (Result <$> minimum <*> maximum <*> mean) &&& (mean . map mean)

mean :: Fractional a => [a] -> a
mean = (/) <$> sum <*> fromIntegral . length

regurgitate :: ([Result], Double) -> String
regurgitate (results, overallMean) = unlines $ [header] ++ body ++ [footer]
  where
    header = " Day   Min   Max   Avg"
    body = zipWith showResult [1..] results
    showResult day (Result mi ma me) = printf " %3d %5.1f %5.1f %5.1f" (day :: Int) mi ma me
    footer = printf "  Average temperature for the month: %5.1f" overallMean

wordsOn :: (a -> Bool) -> [a] -> [[a]]
wordsOn p xs = case dropWhile p xs of
    [] -> []
    xs' -> w : wordsOn p xs''
      where (w, xs'') = break p xs'

stripSpaces :: String -> String
stripSpaces = reverse . dropWhile isSpace . reverse . dropWhile isSpace