Attempt at creating faster sorted keys list for QuantHashes

gistfile1.txt

    method raw_sorted_keys() {
        nqp::if(
          (my $elems := self.raw_hash) && nqp::elems($elems),
          nqp::stmts(
            (my $iter := nqp::iterator($elems)),
            (my $list := nqp::setelems(nqp::list_s,nqp::elems($elems))),
            nqp::bindpos_s(
              nqp::setelems($list,1),
              0,
              nqp::iterkey_s(nqp::shift($iter))
            ),
            (my $inserter := nqp::setelems(nqp::list_s,1)),
            nqp::while(
              $iter,
              nqp::stmts(
                (my int $low = 0),
                (my int $high = nqp::sub_i(nqp::elems($list),1)),
                nqp::bindpos_s(
                  $inserter,
                  0,
                  (my str $target = nqp::iterkey_s(nqp::shift($iter))),
                ),
                nqp::until(
                  nqp::iseq_i($low,$high),
                  nqp::if(
                    nqp::islt_i(
                      nqp::cmp_s(
                        $target,
                        nqp::atpos_s(
                          $list,
                          (my int $i = nqp::div_i(nqp::add_i($low,$high),2))
                        )
                      ),
                      0
                    ),
                    ($high = $i),
                    ($low = nqp::add_i($i,1))
                  )
                ),
                nqp::splice(
                  $list,
                  $inserter,
                  nqp::add_i(
                    $low,
                    nqp::isgt_i(
                      nqp::cmp_s($target,nqp::atpos_s($list,$low)),
                      0
                    )
                  ),
                  0
                )
              )
            ),
            $list
          ),
          nqp::list_s
     }