No-ip updater for Mikrotik

gistfile1.txt

## noip no-ip updater mikrotik behind nat
## read write policy test

# Set needed variables
:local username "username@gmail.com"
:local password "password-no-ip"
:local hostname "domain.ddns.net"

:global dyndnsForce
:global previousIP 

# print some debug info
#:log info ("UpdateNOIP: username = $username")
#:log info ("UpdateNOIP: password = $password")
#:log info ("UpdateNOIP: hostname = $hostname")
:log info ("UpdateNOIP: previousIP = $previousIP")
#:log info ("UpdateNOIP: force = $dyndnsForce")

#if you need set a mangle output mark routing
 /ip firewall address-list add list=dyndns address=checkip.dyndns.org timeout=50s
:delay 3

# get the current IP address from the internet (in case of double-nat)
/tool fetch mode=http address="checkip.dyndns.org" src-path="/" dst-path="/dyndns.checkip.html"
:delay 3
:local result [/file get dyndns.checkip.html contents]

# parse the current IP result
:local resultLen [:len $result]
:local startLoc [:find $result ": " -1]
:set startLoc ($startLoc + 2)
:local endLoc [:find $result "</body>" -1]
:local currentIP [:pick $result $startLoc $endLoc]
:log info "UpdateNOIP: downloadedIP = $currentIP"

# Remove the # on next line to force an update every single time - useful for debugging,
# but you could end up getting blacklisted by DynDNS!

#:set dyndnsForce true

# Determine if dyndns update is needed
# more dyndns updater request details http://www.dyndns.com/developers/specs/syntax.html

:if (($currentIP != $previousIP) || ($dyndnsForce = true)) do={
   :set dyndnsForce false
   :set previousIP $currentIP
   :log info "$currentIP or $previousIP"
   /tool fetch user=$username password=$password mode=http address="dynupdate.no-ip.com" \
      src-path="nic/update\3Fhostname=$hostname&myip=$currentIP" \
      dst-path="/dyndns.txt"
   :delay 2
   :local result [/file get dyndns.txt contents]
   :log info ("UpdateNOIP: Update Result: ".$result)
   :put ("Update Result: ".$result)
} else={
   :log info ("UpdateNOIP: No update needed")
}