nadalao files v1

leatherface.cs

SCRIPT_START
{

LVAR_INT scplayer início carro leatherface dia horas minutos vida1 vida2 colete1 colete2 grupo tempo iDay[2] onMission
LVAR_FLOAT x[3] y[3] z[3]

GET_PLAYER_CHAR 0 scplayer

IF IS_AUSTRALIAN_GAME
    CREATE_CHAR PEDTYPE_SPECIAL SPECIAL04 0.0 0.0 0.0 leatherface
ENDIF

main_loop:
    WAIT 0

    GET_CURRENT_DAY_OF_WEEK dia
    GET_CURRENT_DAY_OF_WEEK iDay[0]
    GET_TIME_OF_DAY horas minutos
    READ_MEMORY 0x96ABA0 1 0 onMission
    
    IF horas >= 0
    AND horas <= 5
    AND NOT iDay[0] = iDay[1]
    AND onMission = FALSE
        SWITCH dia
            CASE 1
                IF LOCATE_CHAR_ANY_MEANS_2D scplayer -1091.7 -1646.4 40.0 40.0 FALSE //leafy hollow
                    GOTO leatherface0
                ENDIF
                BREAK
            CASE 2
                IF LOCATE_CHAR_ANY_MEANS_2D scplayer -378.5 -1431.5 40.0 40.0 FALSE //flint range
                    GOTO leatherface0
                ENDIF
                BREAK
            CASE 3
                IF LOCATE_CHAR_ANY_MEANS_2D scplayer -357.7 -1052.4 40.0 40.0 FALSE //beacon hill
                    GOTO leatherface0
                ENDIF
                BREAK
            CASE 4
                IF LOCATE_CHAR_ANY_MEANS_2D scplayer 1057.7 -321.9 50.0 50.0 FALSE //fazenda hilltop
                    GOTO leatherface0
                ENDIF
                BREAK
            CASE 5
                IF LOCATE_CHAR_ANY_MEANS_2D scplayer -753.2 -130.9 40.0 40.0 FALSE //o panopticon
                    GOTO leatherface0
                ENDIF
                BREAK
            CASE 6
                IF LOCATE_CHAR_ANY_MEANS_2D scplayer -517.2 -116.1 80.0 80.0 FALSE //o panopticon2
                    GOTO leatherface0
                ENDIF
                BREAK
            CASE 7
                IF LOCATE_CHAR_ANY_MEANS_2D scplayer -76.8 27.8 40.0 70.0 FALSE //blueberry acres
                    GOTO leatherface0
                ENDIF
                BREAK
        ENDSWITCH
    ENDIF
            
GOTO main_loop

leatherface0:
    IF IS_CHAR_IN_ANY_CAR scplayer
        GET_CAR_CHAR_IS_USING scplayer carro
    ENDIF
    IF IS_CHAR_SITTING_IN_CAR scplayer carro
        SET_RADIO_CHANNEL 12
        WAIT 1000
        SET_CAR_ENGINE_ON carro FALSE
    ENDIF

    SET_CAR_DENSITY_MULTIPLIER 0.0
    SET_PED_DENSITY_MULTIPLIER 0.0
    SET_WANTED_MULTIPLIER 0.0

    LOAD_SPECIAL_CHARACTER 7 mod01
    WHILE NOT HAS_SPECIAL_CHARACTER_LOADED 7
        WAIT 0
    ENDWHILE
    REQUEST_MODEL CHNSAW
    WHILE NOT HAS_MODEL_LOADED CHNSAW
        WAIT 0
    ENDWHILE

    GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS scplayer 0.0 -1000.0 0.0 x[0] y[0] z[0]
    CREATE_CHAR PEDTYPE_MISSION1 SPECIAL07 x[0] y[0] z[0] leatherface
    SET_CHAR_VISIBLE leatherface FALSE

    GENERATE_RANDOM_INT_IN_RANGE 10000 20000 tempo
    IF LOCATE_CHAR_ANY_MEANS_2D scplayer -517.2 -116.1 80.0 80.0 FALSE //o panopticon2
    OR LOCATE_CHAR_ANY_MEANS_2D scplayer 1057.7 -321.9 50.0 50.0 FALSE //fazenda hilltop
    OR LOCATE_CHAR_ANY_MEANS_2D scplayer -76.8 27.8 40.0 70.0 FALSE //blueberry acres
        tempo += 6000
    ENDIF
    timera = 0
    WHILE NOT timera > tempo
        WAIT 0
    ENDWHILE

    WHILE CLEO_CALL visão 0 scplayer leatherface
        WAIT 0
        GOSUB area
    ENDWHILE

    SET_CHAR_VISIBLE leatherface TRUE
    SET_ANIM_GROUP_FOR_CHAR leatherface oldman
    SET_CHAR_BLEEDING leatherface, TRUE
    GIVE_WEAPON_TO_CHAR leatherface, WEAPONTYPE_CHAINSAW 999
    MARK_MODEL_AS_NO_LONGER_NEEDED CHNSAW
    SET_CHAR_ACCURACY leatherface, 200
    SET_CHAR_SHOOT_RATE leatherface 80
    SET_CHAR_PROOFS leatherface, 0, 1, 0, 1, 0
    SET_CHAR_USES_UPPERBODY_DAMAGE_ANIMS_ONLY leatherface TRUE
    SET_CHAR_SUFFERS_CRITICAL_HITS leatherface FALSE
    SET_CHAR_HEALTH leatherface, 4000
    SET_CHAR_DROPS_WEAPONS_WHEN_DEAD leatherface FALSE
    CREATE_GROUP 0 grupo 
    SET_GROUP_MEMBER grupo leatherface
    UNLOAD_SPECIAL_CHARACTER 7

    TASK_KILL_CHAR_ON_FOOT leatherface scplayer
    iDay[1] = iDay[0]

    WHILE LOCATE_CHAR_ANY_MEANS_CHAR_2D scplayer leatherface 200.0 200.0 FALSE
    AND NOT IS_CHAR_DEAD scplayer
        WAIT 0
        GET_CHAR_HEALTH scplayer vida1
        GET_CHAR_ARMOUR scplayer colete1
        vida2 = vida1
        colete2 = colete1
        WHILE vida2 <= vida1
        AND colete2 <= colete1
        AND LOCATE_CHAR_ANY_MEANS_CHAR_2D scplayer leatherface 200.0 200.0 FALSE
        AND NOT IS_CHAR_DEAD scplayer
            WAIT 0
            GET_CHAR_HEALTH scplayer vida1
            GET_CHAR_ARMOUR scplayer colete1
            IF IS_CHAR_DEAD leatherface
            OR IS_CHAR_DEAD scplayer
                REMOVE_CHAR_FROM_GROUP leatherface
                MARK_CHAR_AS_NO_LONGER_NEEDED leatherface
            ENDIF
        ENDWHILE
        CLEO_CALL dano_leatherface 0 scplayer leatherface
    ENDWHILE

    REMOVE_CHAR_FROM_GROUP leatherface
    REMOVE_GROUP grupo
    MARK_CHAR_AS_NO_LONGER_NEEDED leatherface

    WHILE DOES_CHAR_EXIST leatherface
        WAIT 0
    ENDWHILE
    SET_CAR_DENSITY_MULTIPLIER 1.0
    SET_PED_DENSITY_MULTIPLIER 1.0
    SET_WANTED_MULTIPLIER 1.0

GOTO main_loop

area:
    GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS scplayer 0.0 0.0 0.0 x[0] y[0] z[0]
    GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS scplayer 0.0 0.0 0.0 x[1] y[1] z[1]
    x[0] -= 30.0
    y[0] -= 30.0
    x[1] += 30.0
    y[1] += 30.0
    GENERATE_RANDOM_FLOAT_IN_RANGE x[0] x[1] x[2]
    GENERATE_RANDOM_FLOAT_IN_RANGE y[0] y[1] y[2]
    SET_CHAR_COORDINATES leatherface x[2] y[2] -100.0
RETURN
}

{
LVAR_INT scplayer leatherface
dano_leatherface:
    IF HAS_CHAR_BEEN_DAMAGED_BY_CHAR scplayer leatherface
        DAMAGE_CHAR scplayer 25 1
    ENDIF
CLEO_RETURN 0
}

{
LVAR_INT scplayer leatherface
LVAR_FLOAT x[2] y[2] z[2] distância
visão:
GET_CHAR_COORDINATES leatherface x[0] y[0] z[0]
GET_CHAR_COORDINATES scplayer x[1] y[1] z[1]
GET_DISTANCE_BETWEEN_COORDS_2D x[0] y[0] x[1] y[1] distância
IF z[0] <= 1.0
OR distância < 17.0
OR distância > 100.0
    IS_PC_VERSION
ELSE  
    IF IS_CHAR_ON_SCREEN leatherface
    AND HAS_CHAR_SPOTTED_CHAR leatherface scplayer
        IS_PC_VERSION
    ELSE
        IS_AUSTRALIAN_GAME
    ENDIF
ENDIF
CLEO_RETURN 0
}

SCRIPT_END