Skip to content

Instantly share code, notes, and snippets.

@nadalao

nadalao/70's Horror Movies Myths Mod 3.1

Created June 16, 2018 13:43
Show Gist options
  • Star 0 You must be signed in to star a gist
  • Fork 0 You must be signed in to fork a gist
  • Save nadalao/7df1a99023ac6937d7f20fb32415d05f to your computer and use it in GitHub Desktop.
Save nadalao/7df1a99023ac6937d7f20fb32415d05f to your computer and use it in GitHub Desktop.
Download ZIP
Raw
70's Horror Movies Myths Mod 3.1
SCRIPT_START
{
LVAR_INT iHour iMin audio chance iDay[2] onMission
LVAR_INT scplayer leatherface krueger samara jason michael scream vitima carro
LVAR_FLOAT x y z
GOSUB readini
GET_PLAYER_CHAR 0 scplayer
main_loop:
WAIT 0
READ_MEMORY 0x96ABA0 1 0 onMission
IF onMission = FALSE
//leatherface
IF LOCATE_CHAR_ANY_MEANS_3D scplayer -393.0 -1149.0 69.4 200.0 200.0 200.0 FALSE
GET_TIME_OF_DAY iHour iMin
IF iHour >= 0
AND iHour <= 5
GET_CURRENT_DAY_OF_WEEK iDay[0]
IF CLEO_CALL Randomize 0 chance
AND NOT iDay[0] = iDay[1]
GOTO mito01
ELSE
iDay[1] = iDay[0]
ENDIF
ENDIF
ENDIF
//freddy krueger
IF LOCATE_CHAR_ANY_MEANS_3D scplayer 601.0 1240.0 11.0 150.0 150.0 150.0 FALSE
GET_TIME_OF_DAY iHour iMin
IF iHour >= 0
AND iHour <= 5
GET_CURRENT_DAY_OF_WEEK iDay[0]
IF CLEO_CALL Randomize 0 chance
AND NOT iDay[0] = iDay[1]
GOTO mito02
ELSE
iDay[1] = iDay[0]
ENDIF
ENDIF
ENDIF
//samara
IF LOCATE_CHAR_ANY_MEANS_3D scplayer 1271.0 295.0 20.0 50.0 50.0 50.0 FALSE
GET_TIME_OF_DAY iHour iMin
IF iHour >= 2
AND iHour <= 4
GET_CURRENT_DAY_OF_WEEK iDay[0]
IF CLEO_CALL Randomize 0 chance
AND NOT iDay[0] = iDay[1]
GOTO mito03
ELSE
iDay[1] = iDay[0]
ENDIF
ENDIF
ENDIF
//jason voorhees
IF LOCATE_CHAR_ANY_MEANS_3D scplayer -1617.0 -2265.0 33.0 250.0 250.0 250.0 FALSE
GET_TIME_OF_DAY iHour iMin
IF iHour >= 0
AND iHour <= 5
GET_CURRENT_DAY_OF_WEEK iDay[0]
IF CLEO_CALL Randomize 0 chance
AND NOT iDay[0] = iDay[1]
GOTO mito04
ELSE
iDay[1] = iDay[0]
ENDIF
ENDIF
ENDIF
//michael myers
IF LOCATE_CHAR_ANY_MEANS_3D scplayer -2807.0 1116.0 28.0 150.0 150.0 150.0 FALSE
GET_TIME_OF_DAY iHour iMin
IF iHour >= 0
AND iHour <= 5
GET_CURRENT_DAY_OF_WEEK iDay[0]
IF CLEO_CALL Randomize 0 chance
AND NOT iDay[0] = iDay[1]
GOTO mito05
ELSE
iDay[1] = iDay[0]
ENDIF
ENDIF
ENDIF
//scream
IF LOCATE_CHAR_ANY_MEANS_3D scplayer 1857.0 2771.0 10.0 150.0 150.0 150.0 FALSE
GET_TIME_OF_DAY iHour iMin
IF iHour >= 0
AND iHour <= 5
GET_CURRENT_DAY_OF_WEEK iDay[0]
IF CLEO_CALL Randomize 0 chance
AND NOT iDay[0] = iDay[1]
GOTO mito06
ELSE
iDay[1] = iDay[0]
ENDIF
ENDIF
ENDIF
ENDIF
GOTO main_loop
////////////////////////////////////////////////
mito01: //leatherface
GOSUB carros
LOAD_AUDIO_STREAM "cleo\som01.mp3" audio
SET_AUDIO_STREAM_STATE audio 1
SET_AUDIO_STREAM_LOOPED audio TRUE
LOAD_SPECIAL_CHARACTER 1 mod01
REQUEST_MODEL CHNSAW
REQUEST_MODEL SWMOTR1
WHILE NOT HAS_SPECIAL_CHARACTER_LOADED 1
OR NOT HAS_MODEL_LOADED CHNSAW
OR NOT HAS_MODEL_LOADED SWMOTR1
WAIT 0
ENDWHILE
CREATE_CHAR PEDTYPE_GANG1 SPECIAL01 -387.5 -1145.2 69.2 leatherface
CREATE_CHAR PEDTYPE_CIVFEMALE SWMOTR1 -392.1 -1135.6 69.213966 vitima
UNLOAD_SPECIAL_CHARACTER 1
MARK_MODEL_AS_NO_LONGER_NEEDED SWMOTR1
SET_ANIM_GROUP_FOR_CHAR leatherface oldman
SET_CHAR_BLEEDING leatherface, TRUE
GIVE_WEAPON_TO_CHAR leatherface, WEAPONTYPE_CHAINSAW 999
MARK_MODEL_AS_NO_LONGER_NEEDED CHNSAW
SET_CHAR_ACCURACY leatherface, 200
SET_CHAR_USES_UPPERBODY_DAMAGE_ANIMS_ONLY leatherface, TRUE
SET_CHAR_PROOFS leatherface, 0, 1, 0, 1, 0
SET_CHAR_SUFFERS_CRITICAL_HITS leatherface FALSE
SET_CHAR_HEALTH leatherface, 4000
SET_CHAR_HEALTH vitima 50
SET_CHAR_DROPS_WEAPONS_WHEN_DEAD leatherface FALSE
WHILE NOT LOCATE_CHAR_ANY_MEANS_3D scplayer -393.0 -1149.0 69.4 28.0 28.0 28.0 FALSE
WAIT 0
IF NOT LOCATE_CHAR_ANY_MEANS_3D scplayer -393.0 -1149.0 69.4 250.0 250.0 250.0 FALSE
GOTO release
ENDIF
ENDWHILE
TASK_KILL_CHAR_ON_FOOT leatherface vitima
WHILE NOT IS_CHAR_DEAD vitima
WAIT 0
ENDWHILE
MARK_CHAR_AS_NO_LONGER_NEEDED vitima
WAIT 1500
TASK_SAY scplayer 346
TASK_KILL_CHAR_ON_FOOT leatherface scplayer
iDay[1] = iDay[0]
WHILE LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer leatherface 200.0 200.0 200.0 FALSE
WAIT 0
IF IS_CHAR_DEAD leatherface
OR IS_CHAR_DEAD scplayer
GOTO release
ENDIF
ENDWHILE
GOTO release
mito02: //freddy krueger
GOSUB carros
LOAD_AUDIO_STREAM "cleo\som02.mp3" audio
SET_AUDIO_STREAM_STATE audio 1
SET_AUDIO_STREAM_LOOPED audio TRUE
LOAD_SPECIAL_CHARACTER 2 mod02
REQUEST_MODEL MOLOTOV
WHILE NOT HAS_SPECIAL_CHARACTER_LOADED 2
OR NOT HAS_MODEL_LOADED MOLOTOV
WAIT 0
ENDWHILE
CREATE_CHAR PEDTYPE_GANG1 SPECIAL02 601.3 1240.9 -100.0 krueger
UNLOAD_SPECIAL_CHARACTER 2
GIVE_WEAPON_TO_CHAR krueger, WEAPONTYPE_MOLOTOV 999
MARK_MODEL_AS_NO_LONGER_NEEDED MOLOTOV
SET_CHAR_ACCURACY krueger, 40
SET_CHAR_USES_UPPERBODY_DAMAGE_ANIMS_ONLY krueger, TRUE
SET_CHAR_PROOFS krueger, 0, 1, 0, 1, 0
SET_CHAR_SUFFERS_CRITICAL_HITS krueger FALSE
SET_CHAR_HEALTH krueger, 2000
SET_CHAR_DROPS_WEAPONS_WHEN_DEAD krueger FALSE
WHILE NOT LOCATE_CHAR_ANY_MEANS_3D scplayer 601.3 1240.9 11.7 50.0 50.0 50.0 FALSE
WAIT 0
IF NOT LOCATE_CHAR_ANY_MEANS_3D scplayer 601.3 1240.9 11.7 200.0 200.0 200.0 FALSE
GOTO release
ENDIF
ENDWHILE
WAIT 1500
TASK_SAY scplayer 346
TASK_KILL_CHAR_ON_FOOT krueger scplayer
iDay[1] = iDay[0]
WHILE NOT IS_CHAR_DEAD krueger
WAIT 0
WHILE LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer krueger 80.0 80.0 80.0 FALSE
WAIT 0
IF IS_CHAR_DEAD scplayer
OR IS_CHAR_DEAD krueger
OR iHour >= 6
GOTO release
ENDIF
IF IS_CHAR_SITTING_IN_ANY_CAR scplayer
GET_CAR_CHAR_IS_USING scplayer carro
SET_RADIO_CHANNEL 12
WAIT 2000
SET_CAR_ENGINE_BROKEN carro TRUE
WHILE IS_CHAR_SITTING_IN_ANY_CAR scplayer
WAIT 0
ENDWHILE
ENDIF
ENDWHILE
GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS scplayer 0.0 20.0 0.0 x y z
SET_CHAR_COORDINATES krueger x y -100.0
TASK_SAY scplayer 346
ENDWHILE
GOTO release
mito03: //samara
FORCE_WEATHER_NOW 9
GET_CAR_CHAR_IS_USING scplayer carro
IF IS_CHAR_SITTING_IN_CAR scplayer carro
SET_RADIO_CHANNEL 12
ENDIF
LOAD_AUDIO_STREAM "cleo\som03.mp3" audio
SET_AUDIO_STREAM_STATE audio 1
SET_AUDIO_STREAM_LOOPED audio TRUE
LOAD_SPECIAL_CHARACTER 3 mod03
WHILE NOT HAS_SPECIAL_CHARACTER_LOADED 3
WAIT 0
ENDWHILE
CREATE_CHAR PEDTYPE_GANG1 SPECIAL03 1271.3 295.5 -100.0 samara
UNLOAD_SPECIAL_CHARACTER 3
SET_CHAR_ACCURACY samara, 200
SET_CHAR_SHOOT_RATE samara 200
SET_CHAR_USES_UPPERBODY_DAMAGE_ANIMS_ONLY samara, TRUE
SET_CHAR_PROOFS samara, 1, 1, 1, 1, 0
SET_CHAR_SUFFERS_CRITICAL_HITS samara FALSE
SET_CHAR_HEALTH samara, 1500
WHILE NOT LOCATE_CHAR_ANY_MEANS_3D scplayer 1271.3 295.5 20.6 10.0 10.0 10.0 FALSE
WAIT 0
IF NOT LOCATE_CHAR_ANY_MEANS_3D scplayer 1271.3 295.5 20.6 200.0 200.0 200.0 FALSE
GOTO release
ENDIF
ENDWHILE
WAIT 1500
TASK_SAY scplayer 346
TASK_KILL_CHAR_ON_FOOT samara scplayer
iDay[1] = iDay[0]
WHILE LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer samara 80.0 80.0 80.0 FALSE
WAIT 0
IF IS_CHAR_DEAD samara
OR IS_CHAR_DEAD scplayer
GOTO release
ENDIF
ENDWHILE
GOTO release
mito04: //jason voorhees
GOSUB carros
LOAD_AUDIO_STREAM "cleo\som04.mp3" audio
SET_AUDIO_STREAM_STATE audio 1
SET_AUDIO_STREAM_LOOPED audio TRUE
LOAD_SPECIAL_CHARACTER 4 mod04
REQUEST_MODEL KATANA
WHILE NOT HAS_SPECIAL_CHARACTER_LOADED 4
OR NOT HAS_MODEL_LOADED KATANA
WAIT 0
ENDWHILE
GENERATE_RANDOM_FLOAT_IN_RANGE -1532.473267 -1732.473267 (x)
GENERATE_RANDOM_FLOAT_IN_RANGE -2139.012207 -2339.012207 (y)
CREATE_CHAR PEDTYPE_GANG1 SPECIAL04 x y -100.0 jason
UNLOAD_SPECIAL_CHARACTER 4
GIVE_WEAPON_TO_CHAR jason, WEAPONTYPE_KATANA 999
MARK_MODEL_AS_NO_LONGER_NEEDED KATANA
SET_CHAR_ACCURACY jason, 200
SET_CHAR_USES_UPPERBODY_DAMAGE_ANIMS_ONLY jason, TRUE
SET_CHAR_PROOFS jason, 1, 1, 0, 1, 0
SET_CHAR_SUFFERS_CRITICAL_HITS jason FALSE
SET_CHAR_HEALTH jason, 2000
SET_CHAR_SHOOT_RATE jason 60
SET_CHAR_DROPS_WEAPONS_WHEN_DEAD jason FALSE
WHILE NOT LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer jason 60.0 60.0 60.0 FALSE
WAIT 0
IF NOT LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer jason 300.0 300.0 300.0 FALSE
GOTO release
ENDIF
ENDWHILE
WAIT 1500
TASK_SAY scplayer 346
TASK_KILL_CHAR_ON_FOOT jason scplayer
iDay[1] = iDay[0]
WHILE LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer jason 60.0 60.0 60.0 FALSE
WAIT 0
IF IS_CHAR_DEAD jason
OR IS_CHAR_DEAD scplayer
GOTO release
ENDIF
ENDWHILE
GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS scplayer 0.0 40.0 0.0 x y z
SET_CHAR_COORDINATES jason x y -100.0
TASK_SAY scplayer 346
WHILE LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer jason 200.0 200.0 200.0 FALSE
WAIT 0
IF IS_CHAR_DEAD jason
OR IS_CHAR_DEAD scplayer
GOTO release
ENDIF
ENDWHILE
GOTO release
mito05: //michael myers
FORCE_WEATHER_NOW 9
LOAD_AUDIO_STREAM "cleo\som05.mp3" audio
SET_AUDIO_STREAM_STATE audio 1
SET_AUDIO_STREAM_LOOPED audio TRUE
LOAD_SPECIAL_CHARACTER 5 mod05
REQUEST_MODEL KATANA
WHILE NOT HAS_SPECIAL_CHARACTER_LOADED 5
OR NOT HAS_MODEL_LOADED KATANA
WAIT 0
ENDWHILE
CREATE_CHAR PEDTYPE_GANG1 SPECIAL05 -2794.1 1130.1 -100.0 michael
UNLOAD_SPECIAL_CHARACTER 5
GIVE_WEAPON_TO_CHAR michael, WEAPONTYPE_KATANA 999
MARK_MODEL_AS_NO_LONGER_NEEDED KATANA
SET_CHAR_ACCURACY michael, 200
SET_CHAR_USES_UPPERBODY_DAMAGE_ANIMS_ONLY michael, TRUE
SET_CHAR_PROOFS michael, 0, 1, 0, 1, 0
SET_CHAR_SUFFERS_CRITICAL_HITS michael FALSE
SET_CHAR_HEALTH michael, 4000
SET_CHAR_SHOOT_RATE michael 100
SET_CHAR_DROPS_WEAPONS_WHEN_DEAD michael FALSE
WHILE NOT LOCATE_CHAR_ANY_MEANS_3D scplayer -2807.9 1116.3 28.3 60.0 60.0 60.0 FALSE
WAIT 0
IF NOT LOCATE_CHAR_ANY_MEANS_3D scplayer -2807.9 1116.3 28.3 200.0 200.0 200.0 FALSE
GOTO release
ENDIF
ENDWHILE
WAIT 1500
TASK_SAY scplayer 346
TASK_KILL_CHAR_ON_FOOT michael scplayer
iDay[1] = iDay[0]
WHILE LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer michael 200.0 200.0 200.0 FALSE
WAIT 0
IF IS_CHAR_DEAD michael
OR IS_CHAR_DEAD scplayer
GOTO release
ENDIF
ENDWHILE
GOTO release
mito06: //scream
LOAD_AUDIO_STREAM "cleo\som06.mp3" audio
SET_AUDIO_STREAM_STATE audio 1
SET_AUDIO_STREAM_LOOPED audio TRUE
LOAD_SPECIAL_CHARACTER 6 mod06
REQUEST_MODEL KNIFECUR
WHILE NOT HAS_SPECIAL_CHARACTER_LOADED 6
OR NOT HAS_MODEL_LOADED KNIFECUR
WAIT 0
ENDWHILE
CREATE_CHAR PEDTYPE_GANG1 SPECIAL06 1857.0 2771.8 -100.0 scream
UNLOAD_SPECIAL_CHARACTER 6
GIVE_WEAPON_TO_CHAR scream, WEAPONTYPE_KNIFE 999
MARK_MODEL_AS_NO_LONGER_NEEDED KNIFECUR
SET_CHAR_ACCURACY scream, 200
SET_CHAR_USES_UPPERBODY_DAMAGE_ANIMS_ONLY scream, TRUE
SET_CHAR_PROOFS scream, 0, 1, 0, 0, 0
SET_CHAR_SUFFERS_CRITICAL_HITS scream FALSE
SET_CHAR_HEALTH scream, 2000
SET_CHAR_SHOOT_RATE scream 100
SET_CHAR_DROPS_WEAPONS_WHEN_DEAD scream FALSE
WHILE NOT LOCATE_CHAR_ANY_MEANS_3D scplayer 1857.0 2771.8 10.8 60.0 60.0 60.0 FALSE
WAIT 0
IF NOT LOCATE_CHAR_ANY_MEANS_3D scplayer 1857.0 2771.8 10.8 200.0 200.0 200.0 FALSE
GOTO release
ENDIF
ENDWHILE
WAIT 1500
TASK_SAY scplayer 346
TASK_KILL_CHAR_ON_FOOT scream scplayer
iDay[1] = iDay[0]
WHILE LOCATE_CHAR_ANY_MEANS_CHAR_3D scplayer scream 200.0 200.0 200.0 FALSE
WAIT 0
IF IS_CHAR_DEAD scream
OR IS_CHAR_DEAD scplayer
GOTO release
ENDIF
ENDWHILE
GOTO release
////////////////////////////////////////////////
carros:
FORCE_WEATHER_NOW 9
GET_CAR_CHAR_IS_USING scplayer carro
IF IS_CHAR_SITTING_IN_CAR scplayer carro
SET_RADIO_CHANNEL 12
WAIT 1000
SET_CAR_ENGINE_BROKEN carro TRUE
ENDIF
RETURN
readini:
IF NOT READ_INT_FROM_INI_FILE "cleo\70s_horror_movies_mod.ini" "Settings" "Chance" chance
chance = 99
ENDIF
RETURN
release:
WAIT 2000
SET_AUDIO_STREAM_STATE audio 0
IF DOES_CHAR_EXIST leatherface
REMOVE_CHAR_ELEGANTLY leatherface
ENDIF
IF DOES_CHAR_EXIST krueger
REMOVE_CHAR_ELEGANTLY krueger
ENDIF
IF DOES_CHAR_EXIST vitima
REMOVE_CHAR_ELEGANTLY vitima
ENDIF
IF DOES_CHAR_EXIST samara
REMOVE_CHAR_ELEGANTLY samara
ENDIF
IF DOES_CHAR_EXIST jason
REMOVE_CHAR_ELEGANTLY jason
ENDIF
IF DOES_CHAR_EXIST michael
REMOVE_CHAR_ELEGANTLY michael
ENDIF
IF DOES_CHAR_EXIST scream
REMOVE_CHAR_ELEGANTLY scream
ENDIF
SET_WEATHER_TO_APPROPRIATE_TYPE_NOW
GOTO main_loop
}
{
LVAR_INT iPercent
LVAR_INT iEnd iRandom
Randomize:
GENERATE_RANDOM_INT_IN_RANGE 0 100 (iRandom)
IS_THING_GREATER_THAN_THING iPercent iRandom
CLEO_RETURN 0
}
SCRIPT_END
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment