Skip to content

Instantly share code, notes, and snippets.

@romainl
Last active January 26, 2024 10:36
Show Gist options
  • Star 5 You must be signed in to star a gist
  • Fork 0 You must be signed in to fork a gist
  • Save romainl/f7e2e506dc4d7827004e4994f1be2df6 to your computer and use it in GitHub Desktop.
Save romainl/f7e2e506dc4d7827004e4994f1be2df6 to your computer and use it in GitHub Desktop.
Quickfix alternative to :g/foo/#

Quickfix alternative to :g/foo/#

:help :global is an incredibly cool command.

One thing I like to do with :global is to list lines matching a given pattern in the current file and use that to move around. It looks like this:

:g/let/#
 7         let &path .= 'src/**,public/**,static/**'
 31     unlet b:gqview
 33 nmap <silent> GQ :let b:gqview = winsaveview()<CR>:set opfunc=Format<CR>g@
[...]
:

I like it. I use it all the time.

What if there was a way to persist the result of :[range]g/foo/# and use it to move around?

Well, that's what :[range]Global <pattern> does: it simulates :[range]g/<pattern>/# and populates the location list with the result, allowing us to navigate that list with :help :lnext, :help :lprevious, filter it with :help :Lfilter, operate on each line with :help :ldo, etc.

And :[range]Global! <pattern> does the same but for :[range]g!/<pattern>/#/:[range]v/<pattern>/#.

Neat.

Usage

List all lines with foo:

:[range]Global foo

List all lines without foo:

:[range]Global! foo

My Vim-related gists.

function! Global(pat, bang) range
let operator = a:bang == '!' ? '!~' : '=~'
let padding_top = a:firstline > 1 ? a:firstline - 1 : 0
let bufnr = bufnr()
let qf_title_range = a:firstline == 1 && a:lastline == line('$') ? '%' : a:firstline .. ',' .. a:lastline
let qf_list = getline(a:firstline, a:lastline)
\ ->map({ idx, val -> { 'bufnr': bufnr, 'lnum': idx + 1 + padding_top, 'text': val, 'valid': 1 } })
\ ->filter({ idx, val -> eval("val.text " .. operator .. "'.*' . a:pat . '.*'") })
if qf_list->empty() == 0
call setloclist(win_getid(), [], ' ', { 'title': ':' .. qf_title_range .. 'Global ' .. a:pat, 'items': qf_list })
lwindow
lfirst
endif
endfunction
command! -bang -nargs=1 -range=% Global <line1>,<line2>call Global(<q-args>, expand('<bang>'))
@g0xA52A2A
Copy link

g0xA52A2A commented May 3, 2020

Is there a reason you're avoiding &grepprg in your example? As opposed to say something similar to your "Instant grep + quickfix" gist e.g.

function! Global(...)
  return system(&grepprg . ' ' . join(a:000) . ' ' . expand('%'))
endfunction

command! -nargs=+ -complete=file_in_path -bar Global lgetexpr Global(<f-args>)

augroup quickfix
  autocmd!
  autocmd QuickFixCmdPost lgetexpr lwindow
augroup END

@romainl
Copy link
Author

romainl commented May 3, 2020

I don't use an external program because :g doesn't, that's as far as I've gone about it.

@romainl
Copy link
Author

romainl commented May 3, 2021

Here is a slightly more sophisticated version by @habamax:

command! -bang -nargs=1 Global call setloclist(0, [], ' ',
            \ {'title': 'Global ' .. <q-args>,
            \  'efm':   '%f:%l\ %m,%f:%l',
            \  'lines': execute('g<bang>' .. expand('<bang>') .. '/' .. <q-args> .. '/#')
            \           ->split('\n')
            \           ->map({_, val -> expand("%") .. ":" .. trim(val, 1)})
            \ })

@habamax
Copy link

habamax commented May 3, 2021

too many bangs there:

command! -bang -nargs=1 Global call setloclist(0, [], ' ',
            \ {'title': 'Global ' .. <q-args>,
            \  'efm':   '%f:%l\ %m,%f:%l',
            \  'lines': execute('g<bang>/' .. <q-args> .. '/#')
            \           ->split('\n')
            \           ->map({_, val -> expand("%") .. ":" .. trim(val, 1)})
            \ })

@RaZ0rr-Two
Copy link

RaZ0rr-Two commented Jun 12, 2021

I know this is a bit off-topic but there was a tip on 'where to place custom functions/commands' (or something along those lines), like in which folder in the vim runtimepath. I can't find the gist where it was mentioned unfortunately. So, I am asking here. Sorry :)

@romainl
Copy link
Author

romainl commented Jun 12, 2021

@RaZ0rr-Two

I know this is a bit off-topic but there was a tip on 'where to place custom functions/commands' (or something along those lines), like in which folder in the vim runtimepath. I can't find the gist where it was mentioned unfortunately. So, I am asking here. Sorry :)

If that's a gist of mine you are thinking of, it may be https://github.com/romainl/idiomatic-vimrc.

If you have specific questions, feel free to join us at #vim on libera.chat.

@craigmac
Copy link

@habamax your version isn't working for me until I remove the second argument from the trim() call, like this:

command! -bang -nargs=1 Global call setloclist(0, [], ' ',
            \ {'title': 'Global<bang> ' .. <q-args>,
            \  'efm':   '%f:%l\ %m,%f:%l',
            \  'lines': execute('g<bang>/' .. <q-args> .. '/#')
            \           ->split('\n')
            \           ->map({_, val -> expand("%") .. ":" .. trim(val)})
            \ })

Otherwise you'll get Invalid argument: 1.

@romainl
Copy link
Author

romainl commented Jan 28, 2023

FWIW, this contrived variant of @craigmac's variant of @habamax's variant adds the column number.

command! -bang -nargs=1 Global call setloclist(0, [], ' ',
            \ {'title': 'Global<bang> ' .. <q-args>,
            \  'efm':   '%f:%l:%c\ %m,%f:%l',
            \  'lines': execute('g<bang>/' .. <q-args> .. '/#')
            \           ->split('\n')
            \           ->map({_, val -> expand("%") .. ":" .. trim(val)->substitute('^\d\+','&:' .. trim(val)->substitute('^\d\+ ','','')->charidx(trim(val)->substitute('^\d\+','','')->match(<q-args>)),'')})
            \ })

@romainl
Copy link
Author

romainl commented Jan 26, 2024

FWIW, I made a significant update to this snippet:

  • not a one-liner anymore
  • handles named and unnamed buffers
  • handles arbitrary range
  • sets the quickfix title (inspired by the variations posted in the comments)

Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment