Window Set Iterator

WindowSetIterator.ahk

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

; ATTENTION: requires Autohotkey_L
; alt+shift+a to add
; alt+shift+s to remove
; alt+shift+left to prev
; alt+shift+right to next

; TODO: changing currentWindowSet via hotkey

; ======================================
; Code
; ======================================

#WinActivateForce ; prevent flashing of taskbar buttons

windowSets := {}
currentWindowSet := 1

indexOf(array, item) {
	for index, value in array {
		if(value == item)
			return index
	}
	return 0
}

insertIntoWindowSet(set, winId) {
	; find duplicates
	index := indexOf(set, winId)
	if( index != 0) {
		return
	}
	
	set.insert(winId)
}

removeFromWindowSet(set, winId) {
	; find it
	index := indexOf(set, winId)
	if( index != 0) {
		set.Remove(index)
	}
}

getOrCreateSet(setIndex) {
	global windowSets
	set := windowSets[setIndex]
	if( !set ) {
		set := []
		windowSets[setIndex] := set
	}
	
	return set
}

showWindow(winID) {
	WinActivate, ahk_id %winID%
}

nextWindowInSet(set, currWinID) {	
	if( set.MaxIndex() == 0) {
		return
	}
	
	index := indexOf(set, currWinID)
	
	exists := false
	while ( exists == false )
    	{
		if( set.MaxIndex() == 0) {
			return
		}
		if ( index == 0 || index + 1 > set.MaxIndex()) {
			selected := set[1]
			index := 1
		} else {
			selected := set[index + 1]
			index := index + 1
		}
		exists:=WinExist("ahk_id" selected)
		if ( exists == false ){
			removeFromWindowSet(set, selected)
		}
	}
	showWindow(set[index])
}

previousWindowInSet(set, currWinID) {	
	if( set.MaxIndex() == 0) {
		return
	}
	
	index := indexOf(set, currWinID)
	exists := false
	while ( exists == false )
    	{
		if( set.MaxIndex() == 0) {
			return
		}
		if ( index == 0 || index - 1 < 1) {
			selected := set[set.MaxIndex()]
			index := set.MaxIndex()
		} else {
			selected := set[1]
			index := 1
		}
		exists:=WinExist("ahk_id" selected)
		if ( exists == false ){
			removeFromWindowSet(set, selected)
		}
	}
	showWindow(set[index])
}

; ======================================
; Hotkeys
; ======================================
!+a::
	WinGet, activeWindowID, ID, A
	set := getOrCreateSet(currentWindowSet)
	insertIntoWindowSet(set, activeWindowID)
	return
!+s::
	WinGet, activeWindowID, ID, A
	set := getOrCreateSet(currentWindowSet)
	removeFromWindowSet(set, activeWindowID)
	return

!+Right::
	WinGet, activeWindowID, ID, A
	set := getOrCreateSet(currentWindowSet)
	nextWindowInSet(set, activeWindowID)
	return
	
!+Left::
	WinGet, activeWindowID, ID, A
	set := getOrCreateSet(currentWindowSet)
	nextWindowInSet(set, activeWindowID)
return