extObject.sc

+Object {
	|> {
		|other|
		^other.value(this)
	}

	+> {
		|other, adverb|
		^(this +.(adverb) other.value(this))
	}

	*> {
		|other, adverb|
		^(this *.(adverb) other.value(this))
	}

	++> {
		|other, adverb|
		^(this.asCollection ++.(adverb) other.value(this).asCollection)
	}

	||> {
		|other|
		^this.collect(_ |> other)
	}

	>|| {
		|other|
		^other.collect(this |> _)
	}

	expBlend { arg that, blendFrac = 0.5, min=1;
		var offset = max(0, min - this);
		^blendFrac.linexp(0, 1, this + offset, that + offset) - offset;
	}
}

this looks cool! mind to explain a little what each of the operators do?

I started:

+Object {
	// fold filter around signal
	|> {
		|other|
		^other.value(this)
	}
	// fold filter around signal but also keep original dry signal
	+> {
		|other, adverb|
		^(this +.(adverb) other.value(this))
	}
	// fold filter around signal and multiply (ringmod) with original signal
	*> {
		|other, adverb|
		^(this *.(adverb) other.value(this))
	}
	// Array:add filtered signal to dry signal 
	++> {
		|other, adverb|
		^(this.asCollection ++.(adverb) other.value(this).asCollection)
	}
	// multichannel version of |> 
	||> {
		|other|
		^this.collect(_ |> other)
	}
	// multichannel version of |> but dry signal is this object
	>|| {
		|other|
		^other.collect(this |> _)
	}
	// exponential blend
	expBlend { arg that, blendFrac = 0.5, min=1;
		var offset = max(0, min - this);
		^blendFrac.linexp(0, 1, this + offset, that + offset) - offset;
	}
}