Example AppleScript to Reset Advertising Identifier on macOS under System Preferences -> Security & Privacy

reset_advertising_id.sh

#!/bin/bash

### REF: https://apple.stackexchange.com/questions/357209/automating-reset-advertising-identifier-is-it-possible/357211?noredirect=1#comment471757_357211

osascript << END
if running of application "System Preferences" then
	try
		tell application "System Preferences" to quit
	on error
		do shell script "killall 'System Preferences'"
	end try
end if

repeat while running of application "System Preferences" is true
	delay 0.01
end repeat

tell application "System Preferences"
	activate
	reveal anchor "Privacy" of pane "com.apple.preference.security"
end tell

tell application "System Events" to tell application process "System Preferences"
	
	repeat while not (exists (window "Security & Privacy"))
		delay 0.1
	end repeat
	
	select row 12 of table 1 of scroll area 1 of tab group 1 of window "Security & Privacy"
	
	repeat while not (exists (button "Reset Advertising Identifier" of group 1 of tab group 1 of window "Security & Privacy"))
		delay 0.1
	end repeat
	
	click button "Reset Advertising Identifier" of group 1 of tab group 1 of window "Security & Privacy"
	
	repeat while not (exists (button "Reset identifier" of sheet 1 of window "Security & Privacy"))
		delay 0.1
	end repeat
	
	click button "Reset identifier" of sheet 1 of window "Security & Privacy"
	
	repeat until not (exists (sheet 1 of window "Security & Privacy"))
		delay 0.1
	end repeat
	
end tell

quit application "System Preferences"
END