PKGBUILD

# Maintainer: Christian Mauderer <oss@c-mauderer.de>
# Contributor: Maxwell Pray <synthead@gmail.com>

pkgname=yagv-git
_pkg=yagv
pkgrel=1
pkgver=r21.234ef16
pkgdesc="A fast 3D Gcode Viewer for Reprap-style 3D printers, in Python and OpenGL."
arch=('x86_64')
url="https://github.com/jonathanwin/yagv"
license=('custom')
makedepends=('git')
depends=('python' 'python-pyglet')
conflicts=('yagv')
provides=('yagv')
source=(
  "${pkgname}"::"git+${url}.git"
  "https://patch-diff.githubusercontent.com/raw/jonathanwin/yagv/pull/18.patch"
  "https://patch-diff.githubusercontent.com/raw/jonathanwin/yagv/pull/23.patch"
)
md5sums=(
  'SKIP'
  'a499f4e2255abcd6d6db34f99f3894ff'
  '04271e1c10e97e9d8b8d38ce5afdaa1d'
)

prepare() {
  cd "$srcdir/$pkgname"

  patch -p1 < "$srcdir/18.patch"
  patch -p1 < "$srcdir/23.patch"
}

pkgver() {
  cd "${srcdir}/${pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
  cd "${srcdir}/${pkgname}"

  install -Dm644 "data/hana_swimsuit_fv_solid_v1.gcode" "${pkgdir}/usr/lib/${_pkg}/data/hana_swimsuit_fv_solid_v1.gcode"
  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkg}/data/README.md"
  install -Dm644 "gcodeParser.py" "${pkgdir}/usr/lib/${_pkg}/gcodeParser.py"
  install -Dm755 "yagv" "${pkgdir}/usr/lib/${_pkg}/yagv"

  mkdir -p "${pkgdir}/usr/bin"
  ln -s "/usr/lib/${_pkg}/yagv" "${pkgdir}/usr/bin"
}