bintray generic upload gradle task. Stole directly from https://github.com/pledbrook/lazybones

gistfile1.txt

class BintrayGenericUpload extends DefaultTask {
    @InputFile
    File artifactFile

    @Input
    String artifactUrl

    @TaskAction
    def publish() {

        def username = project.getProperty("repo.username")
        def password = project.getProperty("repo.apiKey")

        def url = new URL(project.getProperty("repo.url") + "/" + artifactUrl)
        logger.lifecycle "Streaming artifact to Bintray at URL ${url}"
        url.openConnection().with {
            // Add basic authentication header.
            setRequestProperty "Authorization", "Basic " + "$username:$password".getBytes().encodeBase64().toString()

            doOutput = true
            fixedLengthStreamingMode = artifactFile.size()
            requestMethod = "PUT"

            def inputStream = artifactFile.newInputStream()
            try {
                outputStream << inputStream
            }
            finally {
                inputStream.close()
                outputStream.close()
            }

            assert responseCode >= 200 && responseCode < 300
        }
    }
}