gistfile1.vb

Sub SomeMethod()
    Using Watch.Measure()
    
        ' other code
        
    End Using ' Output: [Watch] [SomeMethod] xx.xx ms
    
    Using Watch.Measure("customLabel")
    
        ' other code
        
    End Using ' Output: [Watch] [customLabel] xx.xx ms
End Sub

Watch.vb

Imports System.Diagnostics
Imports System.Globalization

Public Module Watch

    Public Function Measure(Optional label As String = Nothing) As IDisposable
        Return New InternalWatch(label)
    End Function

    Private Class InternalWatch
        Implements IDisposable

        Private _label As String
        Private _startTicks As Long
        Private _endTicks As Long

        Public Sub New(label As String)
            If label Is Nothing Then
                _label = New StackFrame(2, True).GetMethod().Name
            Else
                _label = label
            End If
            
            _startTicks = DateTime.Now.Ticks
        End Sub

        Public Overloads Sub Dispose() Implements IDisposable.Dispose
            If _endTicks <> 0 Then Return
            _endTicks = DateTime.Now.Ticks
            Dim duration = TimeSpan.FromTicks(_endTicks - _startTicks)
            Debug.WriteLine(String.Format("[Watch] [{0}] {1} ms", _label, duration.TotalMilliseconds.ToString("0.00", CultureInfo.InvariantCulture)))
        End Sub

    End Class

End Module