count-vowels.clj

;; Try it in the REPL or eval in Light Table

(require '[clojure.string :as string])

(def vowels [:a :e :i :o :u])

(defn char-is-consonant?
  [char]
  (not-any? #{(keyword char)} vowels))

(def char-is-vowel? (complement char-is-consonant?))

(defn string-to-vec
  "Converts a string to a vector of strings"
  [string]
  (vec (drop 1 (string/split string #""))))

(defn count-vowels
  "Returns the number of vowels in a word"
  [word]
  (count (filter char-is-vowel? (string-to-vec word))))

(count-vowels "foobarbazbuzz")
;;-> 5

Couple of notes. Sets are functions and are useful as predicates. Strings are directly filterable as they are sequence of characters. Also Characters have literal representation (as \a below). What do ya think?

(defn count-vowels [word]
  (count (filter #{\a \e \i \o \u} word)))

(count-vowels "foobarbazbuzz") 
;; => 5

You can also use the regex engine:

(defn count-ascii-vowels [s]
  (count (re-seq #"(?i)[aeiou]" s)))

This will likely be the fastest for large inputs

Cool, I didn't realize that strings were directly filterable, and using a set for the filter is nice too. Thanks!