Build audacity with ASIO support on Windows

README.md

Build your own Audacity for Windows with ASIO driver support

You might want Audacity to work with the ASIO drivers supplied with your sound devices. Commmon reasons for this are:

• Only ASIO drivers are available for your hardware (eg Behringer mixers)
• Performance - ASIO has low latency (delays)
• You don't want to use the ASIO4All bridging driver with non ASIO drivers
• Multi channel support - though Audacity is not so good at handling other than Stereo or Mono

Due to licensing restrictions the Audacity team cannot provide a prebuilt version with Windows ASIO driver support. But with this guide and script you can easily build your own Audacity with ASIO support, on a Windows PC.

This builds the latest Audacity release 3.7.0 by default. Recent other versions can be built with the -v option

Background

Drivers are the glue between an audio program like Audacity and external hardware like a mixer or sound interface. The drivers usually used on Windows have limitations which can be overcome if you use ASIO drivers for your hardware. Specifically, low latency (delay) and multi channel support are available with ASIO drivers.

The Audacity program is the "go to" solution for many audio recording and editing tasks. However, unlike many more advanced DAWs, it doesn't support Windows ASIO drivers "out of the box". Fortunately, Audiacity's standard MME support is fine for most uses. That said, common reasons for needing ASIO include using digital audio or music equipment that only comes with ASIO drivers, such as Behringer mixers (which actually suggest using the less efficient ASIO4ALL ASIO to WDM bridging driver). Another common reason is to take advantage of the low latency or multiple channels supported by ASIO. Note that Audacity really is not a good multichannel solution, so if that is required a DAW might be a better bet.

While it is possible to build your own Audacity with ASIO support by following the instructions this usually requires considerable technical skills.

But have no fear, the instructions and script provided here make it easy to build your own version of Audacity with ASIO support. You just need a suitable Windows PC. The script installs all required tools and builds a 64 bit release version of Audacity with ASIO for you using the official build instructions.

NB. If you do use this to build Audacity with ASIO support you must not redistribute it due to the ASIO SDK licensing terms - see below.

Here's a brief blog post explaining why I needed ASIO and it includes a screen shot. But note, since writing that, I discovered my McMillen K-Mix digital interface mixer facilities alow routing of inputs 3 & 4 to the main outputs on 1 and 2 so can use the default MME Audacity build after all. For playback from PC, I found the HiFi Driver and ASIO Bridge from VB Audio lets me re-route PC audio out to channels 3 & 4 on the K-Mix, Leaving Channels 1 & 2 free for instruments and Mics.

Licensing

The reason for Audacity's lack of ASIO support is licensing, not technical. Steinberg do not alow the ASIO SDK to be redistributed (as required by open source projects). In addition, Audacity is GPL licensed and so is incompatible with the ASIO SDK licence redistribution rules.

Development PC

The script installs a set of development tools that are known to build Audacity. Due to the complex nature of such tools, any other versions of them on your PC may interfere with this script. Thus this scipt should be run on a clean PC without any developer tools. No support can be offered otherwise.

If you would rather not install these tools (Git for Windows, Visual Studio, CMake, Python and Conan), or you already have versions of them or even if you are having build problems, you can use a one of the following Vitual Machines:

• Windows Sandbox - Sandbox can be enabled on Windows 10/11 Pro/Enterprise and can also be installed on Windows Home with a bit of effort. If the build experiences memory errors you will need a configuration file to provide more memory than the default 4GB.
• A virtualisation program - install a VM and and a matching Developer Virtual Machine Image from Microsoft. In most cases VirtualBox will be a good choice (import the Microsoft supplied .ova appliance file but the Visual Studio pre installed in the VM must be uninstalled first to avoid problems).

In both cases you can copy the built files to where they will be run from on you PC file system, possibly by sharing a PC folder with the VM.

Step by Step Instructions

• Ensure you have a PC (or VM) with Windows 10 or 11 installed.
• Make a new folder C:\projects.
• Click on the 'raw' button at the top of the script (below) in this Gist.
• Use the browser Save As (right click) feature to save the script as This PC -> C:\projects\build-audacity.cmd. To avoid it being saved as a text file type the filename in quotes, eg "build-audacity.cmd".
• open a new Windows cmd terminal (Windows + R keys and then type cmd)
• Type cd \projects and enter key.
• Install required tools and build by typing build-audacity.cmd and enter (use -v3.3.3 if requred).
  • Follow the prompts, pressing a key to start each tool's installer (when previous has finished).
  • NB for Visual Studio, make sure you check the "desktop development with C++" workload
  • If you have a non English Windows or Visual Studio then you must also install the English language packs.
• Come back later - it will take at least 10 minutes.
• Audactiy will be launched to test it was built correctly.
  • See the program location printed out at the end of the build so you can run it again.
  • Optionally copy the specified folder to where you want to run Audacity from, optionally renaming it.

(This video by @Renamesk walks you through the process, but the tool installation method has changed.)

If you have any ASIO drivers installed for active connected hardware you should find ASIO is now available in the the Audacity driver selection combo box which probably currently shows 'MME' selected (you may need to show using menu item View -> Toolbars -> Device toolbar).

NB: The Audacity settings and preferences are stored in a folder "Portable Settings" next to the audacity program. If you want to use settings in the user's home directory then delete this folder.

When things go wrong

As with any complex software build there are many moving parts (including Windows itself) and things can sometimes go wrong. Here are some tips if you hit build errors.

If everyhting falls or you just want to shortcut lots of painful debugging then try a Microsoft Windows Virtual machine (VM) as mentioned above.

• make sure you have latest script
• make sure you are in a folder C:\projects in the cmd window
• ensure you are an administrator on your Windows 10 or 11 64 bit PC (ie not a organisational PC)?
• run the script with --cleanall and try again
• uninstall all the tools and installers (Python, cmake, Visual Studio) and then reboot before trying again
  • note having other versions of any of the tools installed may well cause problems - remove them
• ensure you ticked the specified options when installing Visual Studio and Python, reinstall if unsure
• read the error output - clues are often buried in reams of impenetrable text
• disable any Anti Virus - the built-in Microsoft one is usually not a problem
• if your PC is not English make sure you have EN language packs installed for Windows and VS

Thanks

• @diogodh for finding and fixing the bug with conan installations
• The Audacity team for an fantastic audio tool

build-audacity.cmd

@echo off
rem Version: 2.10.0
rem
rem Build audacity with ASIO support on Windows
rem See the following gist for details
rem  https://gist.github.com/SteveALee/da24c2be633340b8791066dd98eb5d0b
rem
rem Options (only one may be specified)
rem
rem --install or none - install tools and build
rem --build - build, no install
rem --noget - build only but don't fetch again from git
rem --getonly - only get the files 
rem --rebuild - cleanall and build
rem --clean - remove built files
rem --cleanall - remove fetched, built files and conan modules
rem --cleaninstall - remove downloaded installation files
rem -vj.m.p version - default is 3.7.0 (using conan 2.3.2) - limited due to dependencies
rem
rem MIT licence
rem steve@fullmeasure.co.uk

TITLE Build Audacity with ASIO

setlocal
rem Clean up arguments
set TARGET=%1
set VERSION=%2
rem substring on empty var fails within parenthesis
if not [%TARGET%] == [] set TARGET_PREFIX=%TARGET:~0,2%
if [%TARGET_PREFIX%] == [-v] (
  set TARGET=%2
  set VERSION=%1
)
if [%TARGET%] == [] set TARGET=--install
if [%VERSION%] == [] (
  set AUDACITY_REL=3.7.0
) else (
  set AUDACITY_REL=%VERSION:~2%
)

set VISUALSTUDIOVER=2022\Community
set VISUALSTUDIOCMAKE=Visual Studio 17 2022
set VSDIR=%ProgramFiles%\Microsoft Visual Studio\%VISUALSTUDIOVER%
set PROJROOT=C:\projects
set AUDACITY=%PROJROOT%\audacity
set AUDACITY_BUILD=%PROJROOT%\audacity-asio
set MAKE_CONFIG=RelWithDebInfo
set EXEDIR=%AUDACITY_BUILD%\%MAKE_CONFIG%
set INSTALLFILEDIR=bin
rem More vaiables set for --install
if [%AUDACITY_REL:~0,3%] == [3.3] (set CONAN_VER=1.59.0) else (set CONAN_VER=2.3.2)
set CMAKE_OPTS=-DAUDACITY_BUILD_LEVEL=2 -Daudacity_has_asio_support=On
if [%AUDACITY_REL:~0,3%] == [3.5] set CMAKE_OPTS=%CMAKE_OPTS% -Daudacity_has_audiocom_upload=On -Daudacity_has_networking=On -Daudacity_has_url_schemes_support=On
if [%AUDACITY_REL:~0,3%] == [3.6] set CMAKE_OPTS=%CMAKE_OPTS% -Daudacity_has_audiocom_upload=On -Daudacity_has_networking=On -Daudacity_has_url_schemes_support=On
if [%AUDACITY_REL:~0,3%] == [3.7] set CMAKE_OPTS=%CMAKE_OPTS% -Daudacity_has_audiocom_upload=On -Daudacity_has_networking=On -Daudacity_has_url_schemes_support=On

rem check projroot exists
if /I not [%~dp0] == [%PROJROOT%\] (
  echo.
  echo Error: This script must be run in %PROJROOT% - see %%PROJROOT%% in file
  echo.
  if not exist %PROJROOT% (
    echo Create %PROJROOT
    goto exit
) else (
  echo cd to %PROJROOT%
  goto exit
)
)

echo.
echo Building Audacity %AUDACITY_REL% 64 bit RelWithDebInfo with ASIO support...
echo.

rem Get tools
rem ANSI escape sequences do not work in if () block so we use goto

set git-url=https://github.com/git-for-windows/git/releases/download/v2.47.0.windows.1/Git-2.47.0-64-bit.exe
set GITPATH=%ProgramFiles%\Git\cmd\
set vs2022-url=https://aka.ms/vs/17/release/vs_community.exe
rem Conan is installed later
if [%CONAN_VER%] == [1.59.0] (
  rem Note Conan 1.59 has dependency issues with python 3.12
  set python-url=https://www.python.org/ftp/python/3.11.0/python-3.11.0-amd64.exe
  set PYTHONPATH=%LOCALAPPDATA%\Programs\Python\Python311\
) else (  
  set python-url=https://www.python.org/ftp/python/3.13.0/python-3.13.0-amd64.exe
  set PYTHONPATH=%LOCALAPPDATA%\Programs\Python\Python313\
)
set PIPPATH=%PYTHONPATH%Scripts\
   
if not [%TARGET%] == [--install] if not [%TARGET%] == [--cleaninstall] goto clean

if [%TARGET%] == [--cleaninstall] echo Cleaning installation files... & rmdir /s/q %INSTALLFILEDIR% 2> :null & goto exit

echo   
echo.
echo Fetching tools..
echo 

mkdir %INSTALLFILEDIR% 2> :null
curl -L %git-url% -o %INSTALLFILEDIR%\g4w.exe
curl -L %vs2022-url% -o %INSTALLFILEDIR%\vs.exe
curl -L %python-url% -o %INSTALLFILEDIR%\python.exe

echo   
echo.
echo Installing tools...
echo.
echo IMPORTANT!! Follow the instructions below for each installer
echo Close each installer when it is done before starting next
echo.
echo Git for Windows
echo Choose the option "Git from the command line..."
pause
%INSTALLFILEDIR%\g4w.exe
echo.
echo Visual Studio: make sure you select the Workload "Desktop development with C++"
echo You can uncheck "Start After installation"
pause
%INSTALLFILEDIR%\vs.exe
echo.
echo Python: make sure you select "Add python.exe to PATH" for future access
pause
%INSTALLFILEDIR%\python.exe
echo.

echo.
echo 
set installing=true
call :clean --rebuild
goto exit

rem subroutine
:cleanall
echo Cleaning source and built files... & rmdir /s/q %AUDACITY% %AUDACITY_BUILD% 2> :null
where /q conan & if ERRORLEVEL 0 echo Cleaning conan cache... & conan remove -c "*" 2>&1 > :null
exit /B

:clean
rem Python is on path, unless in windows sandbox
rem where /q python & if ERRORLEVEL 1 path %PATH%;%PYTHONPATH%
rem where /q pip & if ERRORLEVEL 1 path %PATH%;%PIPPATH%
rem where /q git & if ERRORLEVEL 1 path %PATH%;%GITPATH%
path %PYTHONPATH%;%PIPPATH%;%GITPATH%;%PATH%

if not [%TARGET%] == [--getonly] (
  if /I [%TARGET%] == [--clean] echo Cleaning built files... & rmdir /s/q %AUDACITY_BUILD% 2> :null & goto exit
  if /I [%TARGET%] == [--cleanall] call :cleanall & goto exit
  if /I [%TARGET%] == [--rebuild] call :cleanall
)

rem Launch cmake-gui
rem VS doesn't include this with it's cmake
rem if [%TARGET%]==[--gui] cmake-gui -Daudacity_has_asio_support=On %CMAKE_OPTS% -S %AUDACITY% -B %AUDACITY_BUILD% & goto build

:checktools
rem ensure tools are installed
if not [%TARGET%] == [--noget] (
  where /q git & if ERRORLEVEL 1 echo Git for Windows does not appear to be installed. Re run with "--install" & goto exit /b
)
if not [%TARGET%] == [--getonly] (
  if not exist "%VSDIR%\VC\Auxiliary\Build\vcvars64.bat" echo Visual Studio does not appear to be installed. Re run with "--install" & goto exit /b
  if not defined VisualStudioVersion call "%VSDIR%\VC\Auxiliary\Build\vcvars64.bat"
  where /q python & if ERRORLEVEL 1 echo Python does not appear to be installed. Open a new cmd window or re-run with "--install" & goto exit /b
  where /q conan & if ERRORLEVEL 0 pip show --version conan | findstr /R /C:"Version: %CONAN_VER%" & if ERRORLEVEL 1 echo conan %CONAN_VER% not found & pip uninstall -y -q conan
  where /q conan & if ERRORLEVEL 1 echo installing conan %CONAN_VER% & pip install conan==%CONAN_VER%
)

rem Get source code
:getcode
if /I not [%TARGET%] == [--clean] (
  if /I not [%TARGET%] == [--cleanall] (
    if /I not [%TARGET%] == [--noget] (
      echo Fetching code for Audacity %AUDACITY_REL%...
      echo.
      git clone -b Audacity-%AUDACITY_REL% --depth 1 https://github.com/audacity/audacity/ %AUDACITY%
      if ERRORLEVEL 1 echo Error: cannot fetch the Audacity code. Try the --cleanall or --noget options & goto exit
    )
  )
)

if /I [%TARGET%] == [--getonly] goto exit

if not exist %AUDACITY%\CMakeLists.txt echo The code files appear to be missing from %AUDACITY%. & goto exit

:cmake
cd %AUDACITY%
cmake.exe -G "%VISUALSTUDIOCMAKE%" -DCMAKE_CONFIGURATION_TYPES=%MAKE_CONFIG% %CMAKE_OPTS% -S %AUDACITY% -B %AUDACITY_BUILD% & if ERRORLEVEL 1 echo Error: Cannot create Audacity buildfiles & goto exit

:build
cd %AUDACITY_BUILD%
set msbuild="%VSDIR%\MSBuild\Current\Bin\MsBuild.exe"
%msbuild% ALL_BUILD.vcxproj -p:configuration=%MAKE_CONFIG%
if ERRORLEVEL 1 echo Error: cannot build Audacity & goto exit

rem Settings stored with files rather than home directory
rem See https://manual.audacityteam.org/man/portable_audacity.html
mkdir %EXEDIR%\"Portable Settings"

cd %PROJROOT%

rem All done
echo 
echo.
echo Congratulations!
echo Your new Audacity %AUDACITY_REL% with ASIO support will now launch.
echo The ASIO options will appear if you have ASIO drivers and connected hardware
echo In future just run the audacity.exe. No need to install.
echo.
echo    %EXEDIR%\audacity.exe
echo.
echo Or copy the folder
echo.
echo    %EXEDIR%\
echo.
echo and run the included audacity.exe
echo.
echo Note settings and preferences are stored in "%EXEDIR%\Portable Settings"
echo If you want to use settings in the user's home directory then delete this folder.
echo.
echo 
start %EXEDIR%\audacity.exe
if defined installing exit /B

:exit
cd %PROJROOT%
endlocal

Thank you very much, @SteveALee !
I used to get Audacity compiled without any fears, but that was years ago... (Audacity 2.0.3).
Now I tried to get the latest 3.2.1 built, because of the new feature "Real-Time effects" - but failed...

I already had VS2017 installed and thought it would be okay - but it wasn't.
After trying several manual ways and tried to modify your script to use VS2017, I finally found that CMake seems to fail to create x64 configs for VS2017.
My last resort was to download and install a more recent Visual Studio and can now report:
Your script still works for Audacity 3.2.1, CMake 3.25.0, Python 3.11.0 and Visual Studio 2022!

If anyone is interested, here is my modified version for easy selecting the versions of all 4 tools on updates in the future:
https://gist.github.com/Giermann/c3f88ee2a147f9a688a2ca76e1334a54

@Giermann hey, congrats and thanks for the heads up that VS 2022 is usable!! That's great to know. This build stuff can be so fragile, which of course is why I created the script in the first place. :D

Thanks @SteveALee, your code encouraged me finally to try to build Audacity with Asio support. I always feared to install so much software only to create a program only once on my limited computer. Finally I used a Win11 virtuell machine offered by Microsoft (https://developer.microsoft.com/de-de/windows/downloads/virtual-machines/) using Virtualbox that needs a lot of Gigabytes but includes Visual Studio 2022. In this virtuell machine I only needed to install Git, CMake und Python to run build-audacity.cmd. That worked well for me.

@haberl333 fantastic! That was a great thing to find out and I hope you enjoy it. I did not realise Windows VMs were available, thinking licencing would be a blocker. Those dev VMss are really useful. Using VMs or more recently, containers, are vital if you arexworking on lots of projects and I like how you suggest also keep all those tools from cluttering up you PC. I'll add a note. Thanks again

@dolfff Agree - it's a bit sidelined right now and ASIO is common. Wish I had bandwidth to help drive it a bit.

Amazing, it worked!..Now I can use Audacity-ASIO to connect with my Mackie ProFX V3 USB mixer; these newer V3 models do NOT use Window USB class compliant drivers but rather (first time for Mackie I believe) are dependent on Mackie (Loud corp) USB drivers which are downloadable from Mackie.com. Audacity is very confused in detecting the Windows Audio device passthrough which Audacity without ASIO is dependent on to get a successful Recording and Playback Audio setup.

Because I installed VS (Desktop with C++ ver) 2022 on my D: partition (I have a relatively small C: reserved primarily for Win 10 OS) I needed to adjust the path to VS in audacity-asio.cmd to point there.
I was worried as it ran as build-audacity.cmd seemed to restart the VS build routines several times and threw tons of Warnings. Warnings mostly involved components which were missing or the wrong version but eventually the script recovered after many had to be downloaded and updated (haven't checked the error list yet to try to understand all that). Total build took about 12 minutes to complete but finally got the Success! and "Where to find the audacity.exe" msg; it just in your c:\project folder which was created as recommended in the first steps.
Question...This new audacity-asio destination folder seems to have lots of .cmake files (and other files part of the build/make process creating a folder of around 491mb). Can I delete any of these or are these required to be left in place?

Can I delete any of these or are these required to be left in place?

You may delete any files, that are not present in a normal Audacity installation.
In fact, you may also only replace the "portaudio_x64.dll" from an official distribution with that newly built one.

@mapper14 Congratulations and thanks for sharing. DOS/Windows use of separate drives is the source of so many problems. You were lucky. My guess is the CMake phase referenced all libs on C: when they were actually on D:. It's amazing VS dealt with it, with a double install. It might have been possible to address that, but life's too short :)

What @Giermann said re all those build artifact files. And it's great to know that only that DLL required.

BTW I wonder if you don't get much better latency than the old bridging driver which appeared to me to be a complete bodge.

Well, sorry to have to retract my enthusiasm now because with actual testing with my Mackie ProFX10V3 the s*** really hits the cooling fan! Although Audacity does run (the startup is extremely slow on my i5 laptop-almost 30 sec to get the splash screen!) the ASIO implementation in this build behaves very strangely when connected to the Mackies. Audacity Audio-Interface choices now add ASIO to the usual Windows MME, WASAPI and Direct Sound. Playback device choice now gives the usual Windows options for my laptop, Realtek HD speakers, headphones, plus ASIO. However the ASIO control panel acts very strangely; the ASIO tray icon has got to two vertical lines (not the fatal warning exclamation marks however) and flashes. ASIO control panel does open but does not display my ProFX bridged drivers correctly. On other ASIO compliant DAWs (such as Tracktion Waveform and Ableton) the ASIO panel correctly shows base ProFX plus two branches, one for the ProFX channel 1-2 and the other for ProFX channel 3-4 and either branch or both can be turned on or off. When the channel branch is ON, the DAW detects and uses that under its Interface-Device pull downs. I suspect these multichannel ASIO devices and drivers cause additional compatibility grief with this version of the audacity-asio build. Lord knows what the Allen Heath 4 channel USB mixers would show! The final (and fatal) defect shows up when Audacity-ASIO is actually connected to the ASIO-Mackie bridge and the input sound turns on for a few seconds, then turns off and keeps cycling and nothing comes through when the Record Monitor is clicked. Guess if I want to pursue this I'll have to dig into the code as to how the version of the ASIO base code is married to the audacity base. I'm pretty rusty on VS Make files so I have to rely on these cookbook scripts for now. I'd really love to hear if any Audacity geeks have any further experiences (good or bad) with the actual nuanced usages and behaviour after building and running audacity-asio. Cheers for now, Mike

Sigh! So two possibilities come to mind 1) the Audacity ASIO support isn't working with your setup, or 2) the build is barfed even though it appears to work. I'll try to explore 2) in the next couple of days, but can't promise.

@mapper14 I had a quick look and Visual Studio only lets you change the installation location of some components. I don't know if all required parts will be moved or not so adjusting the path in script may or may not work. I can't support this I'm afraid. If you really don't have room for VS and the build on C: I suggest your find another PC to build on.

Steve; Actually did get a successful build (with many compiler restarts and downloading of missing components, but the compile did complete and it runs-see my posts here) However there are massive problems with the way ASIO behaves when connecting to audacity-asio. In my setup with a Mackie ProFX V3 mixer ASIO becomes 'bridged' with a proprietary Mackie USB driver which rides below the running ASIO4ALL. The Mackie USB driver is REQUIRED with the newer V3 Mackie USB mixers, their USB implementation is not compliant with the built-in Windows 10 Microsoft USB driver. When I fire up audacity-asio it does invoke ASIO4All and the Mackie USB driver in combination but the setup is very unstable. The ASIO icon in my Windows tray flashes with vertical bars and the sound that does come through is intermittent cutting in and out, so obviously there is some incompatibility with the audacity-asio and the Mackie USB driver. The Mackie USB driver and ASIO4All work fine when running a commercial DAW such as Tracktion or Ableton so I know that the Mackie USB driver and ASIO4All combo does works and is stable. -Mike

…

On Mon, Feb 6, 2023 at 12:29 PM Steve Lee ***@***.***> wrote: ***@***.**** commented on this gist. ------------------------------ @mapper14 <https://github.com/mapper14> I had a quick look and Visual Studio only lets you change the installation location of some components. I don't know if all required parts will be moved or not so adjusting the path in script may or may not work. I can't support this I'm afraid. If you really don't have room for VS and the build on C: I suggest your find another PC to build on. — Reply to this email directly, view it on GitHub <https://gist.github.com/da24c2be633340b8791066dd98eb5d0b#gistcomment-4462052> or unsubscribe <https://github.com/notifications/unsubscribe-auth/AB5AYGJBLFWWP6VYT5ZBA53WWFNKFBFKMF2HI4TJMJ2XIZLTSKBKK5TBNR2WLJDHNFZXJJDOMFWWLK3UNBZGKYLEL52HS4DFQKSXMYLMOVS2I5DSOVS2I3TBNVS3W5DIOJSWCZC7OBQXE5DJMNUXAYLOORPWCY3UNF3GS5DZVRZXKYTKMVRXIX3UPFYGLK2HNFZXIQ3PNVWWK3TUUZ2G64DJMNZZDAVEOR4XAZNEM5UXG5FFOZQWY5LFVEYTAMRQGM2TANJZU52HE2LHM5SXFJTDOJSWC5DF> . You are receiving this email because you were mentioned. Triage notifications on the go with GitHub Mobile for iOS <https://apps.apple.com/app/apple-store/id1477376905?ct=notification-email&mt=8&pt=524675> or Android <https://play.google.com/store/apps/details?id=com.github.android&referrer=utm_campaign%3Dnotification-email%26utm_medium%3Demail%26utm_source%3Dgithub> .

As this Gist is only to help people compiling Audacity with ASIO support, I'd suggest to report the issue here.

Thanks @Giermann and +1

@mapper14 a build can in theory complete without errors but not be correct. It appears to me that VS only allows the libs etc to be in c:\Program Files... so if you edited the script to say they are in D:\ I'd say your build config is indeterminate.

Also ASIO4ALL is the "bodge" driver I had in mind in my previous comment. AfAIK it makes windows drivers look like ASIO but without any of the multichannel or speed advantages. I suggest if you see it being used you have a run time config issue which you can best take to the Audacity team for support Best of luck.

So VS MUST be in installed in C:\program files to get a good fully functional build ? - even though the make script reported 'success' and pointed to the new .exe as output. If so, then I guess the make script isn't checking the validity of all intermediate steps or ?

…

On Tue, Feb 7, 2023, 12:24 AM Steve Lee ***@***.***> wrote: ***@***.**** commented on this gist. ------------------------------ Thanks @Giermann <https://github.com/Giermann> and +1 @mapper14 <https://github.com/mapper14> a build can in theory complete without errors but not be correct. It appears to me that VS only allows the libs etc to be in c:\Program Files... so if you edited the script to say they are in D:\ I'd say your build config is indeterminate. Also ASIO4ALL is thec"bodge" driver I had in mind in my previous comment. AfAIK it makes windows drivers look like ASIO but without any of the multichannel or speed advantages. I suggest if you see it being used you have a run time config issue which you can best take to the Audacity team for support Best of luck. — Reply to this email directly, view it on GitHub <https://gist.github.com/da24c2be633340b8791066dd98eb5d0b#gistcomment-4462702> or unsubscribe <https://github.com/notifications/unsubscribe-auth/AB5AYGNHP35B2P3VI3BU4W3WWIBFPBFKMF2HI4TJMJ2XIZLTSKBKK5TBNR2WLJDHNFZXJJDOMFWWLK3UNBZGKYLEL52HS4DFQKSXMYLMOVS2I5DSOVS2I3TBNVS3W5DIOJSWCZC7OBQXE5DJMNUXAYLOORPWCY3UNF3GS5DZVRZXKYTKMVRXIX3UPFYGLK2HNFZXIQ3PNVWWK3TUUZ2G64DJMNZZDAVEOR4XAZNEM5UXG5FFOZQWY5LFVEYTAMRQGM2TANJZU52HE2LHM5SXFJTDOJSWC5DF> . You are receiving this email because you were mentioned. Triage notifications on the go with GitHub Mobile for iOS <https://apps.apple.com/app/apple-store/id1477376905?ct=notification-email&mt=8&pt=524675> or Android <https://play.google.com/store/apps/details?id=com.github.android&referrer=utm_campaign%3Dnotification-email%26utm_medium%3Demail%26utm_source%3Dgithub> .

I just tried this on a clean Windows 11 VM... Installed VS, python and git (and checkpointed the VM)... then ran the script... and here it dies... f:\audacity is set as PROJROOT.

Any help is appreciated!

Building Audacity 3.2.3 64 bit release with ASIO support...

-- Conan: checking conan executable
-- Conan: Found program CONAN_CMD-NOTFOUND
CMake Error at cmake-proxies/cmake-modules/conan.cmake:813 (message):
Conan --version failed='The system cannot find the file specified'
Call Stack (most recent call first):
cmake-proxies/cmake-modules/AudacityDependencies.cmake:18 (conan_check)
CMakeLists.txt:237 (include)

-- Configuring incomplete, errors occurred!
See also "F:/audacity/audacity-asio/CMakeFiles/CMakeOutput.log".
Error: Cannot create Audacity buildfiles

f:\audacity>

Found the problem... conan existed and could be found, but not in the same path as python.exe... so I copied it from where it was to the scripts directory for the python that is in \program files\ directory... problem solved...

Now, how can I tell if I have ASIO properly installed? I don't see it anywhere, and my dev machine and the machine attached to the mixer are not the same... I don't want to go and expect it to work, and then there is something else... Thanks!

Just open the Audio host submenu somewhere (in toolbar or Audio settings) and you should find "ASIO" there:

I was just thinking... the first comment on this issue was on 2020. Almost 3 years ago. Isn't this something we couldn't try to merge with the main project now that it switched hands and they are revamping and improving Audacity considerable in such a short time span? What do you think? Is this doable? Is this possible?

@rvyhmeister the fact its F: not C: as most common and tested indicates there might path issues.

Oops, missed other comments

@Giermann thanks

@victorwestmann works form me. I'm sure even devs would appreciate easy build, at least for first build. And also those wanting to provide a drive by pull request. CC @Tantacrul

Hmm... I don't show the ASIO as shown by @Giermann. As I re-read the instructions it says that I must have ASIO drivers installed. I do have them installed, but they're not active, since I'm not connected to the ASIO mixer... So how do I get the ASIO drivers into Audacity? Or will ASIO show up magically when I run audacity on the machine connected to the mixer?

@rvyhmeister try when connected to the active hardware. Otherwise, please ask over in the Audacity community as this Gist is about building only.

I had to "pip uninstall conan" and" pip install conan==1.59.0" for the script to work. Apparently conan 2.0 was just released and the commands are different. Reference: audacity/audacity#4360

@MarkMayhew oh brilliant!! What happened to backward compatability!? Thanks for the heads up.

@rvyhmeister try when connected to the active hardware. Otherwise, please ask over in the Audacity community as this Gist is about building only.

When connected to active hardware, ASIO showed up and worked! Thanks to all!

@rvyhmeister that's excellent news. Thanks for sharing.

@MarkMayhew I updated the script. Thanks again.

I got it to work as well, but it doesn't function as I expected, I've got a live instrument feed through a Focusrite Scarlett Solo. I am able to select the Scarlett Solo as the ASIO input and output in Audacity now, and it records the instrument through the Scarlett Solo just fine, but I cannot figure out how to configure Audacity to let me hear the instrument (other than playback of what was recorded). So, I can play the recording and hear the instrument in the recording, but I cannot hear the instrument "live." Has anyone else been successful making this work that may be able to help me? Thank you!

@steadybright Best ask the Audacity community as this gist is just about building with ASIO enabled.

That said it sounds like you need something else to play sounds coming in from your device when Audacity is not doing anything. Windows itself probably doesn't see the ASIO drivers at all. Have a look in control panel sound settings.

I'd expect audacity to let you hear when it's recording, so maybe select record and pause?

Updated to Audacity 3.3.2