Build audacity with ASIO support on Windows

README.md

Build your own Audacity for Windows with ASIO driver support

You might want Audacity to work with the ASIO drivers supplied with your sound devices. Commmon reasons for this are:

• Only ASIO drivers are available for your hardware (eg Behringer mixers)
• Performance - ASIO has low latency (delays)
• You don't want to use the ASIO4All bridging driver with non ASIO drivers
• Multi channel support - though Audacity is not so good at handling other than Stereo or Mono

Due to licensing restrictions the Audacity team cannot provide a prebuilt version with Windows ASIO driver support. But with this guide and script you can easily build your own Audacity with ASIO support, on a Windows PC.

This builds the latest Audacity release 3.7.0 by default. Recent other versions can be built with the -v option

Background

Drivers are the glue between an audio program like Audacity and external hardware like a mixer or sound interface. The drivers usually used on Windows have limitations which can be overcome if you use ASIO drivers for your hardware. Specifically, low latency (delay) and multi channel support are available with ASIO drivers.

The Audacity program is the "go to" solution for many audio recording and editing tasks. However, unlike many more advanced DAWs, it doesn't support Windows ASIO drivers "out of the box". Fortunately, Audiacity's standard MME support is fine for most uses. That said, common reasons for needing ASIO include using digital audio or music equipment that only comes with ASIO drivers, such as Behringer mixers (which actually suggest using the less efficient ASIO4ALL ASIO to WDM bridging driver). Another common reason is to take advantage of the low latency or multiple channels supported by ASIO. Note that Audacity really is not a good multichannel solution, so if that is required a DAW might be a better bet.

While it is possible to build your own Audacity with ASIO support by following the instructions this usually requires considerable technical skills.

But have no fear, the instructions and script provided here make it easy to build your own version of Audacity with ASIO support. You just need a suitable Windows PC. The script installs all required tools and builds a 64 bit release version of Audacity with ASIO for you using the official build instructions.

NB. If you do use this to build Audacity with ASIO support you must not redistribute it due to the ASIO SDK licensing terms - see below.

Here's a brief blog post explaining why I needed ASIO and it includes a screen shot. But note, since writing that, I discovered my McMillen K-Mix digital interface mixer facilities alow routing of inputs 3 & 4 to the main outputs on 1 and 2 so can use the default MME Audacity build after all. For playback from PC, I found the HiFi Driver and ASIO Bridge from VB Audio lets me re-route PC audio out to channels 3 & 4 on the K-Mix, Leaving Channels 1 & 2 free for instruments and Mics.

Licensing

The reason for Audacity's lack of ASIO support is licensing, not technical. Steinberg do not alow the ASIO SDK to be redistributed (as required by open source projects). In addition, Audacity is GPL licensed and so is incompatible with the ASIO SDK licence redistribution rules.

Development PC

The script installs a set of development tools that are known to build Audacity. Due to the complex nature of such tools, any other versions of them on your PC may interfere with this script. Thus this scipt should be run on a clean PC without any developer tools. No support can be offered otherwise.

If you would rather not install these tools (Git for Windows, Visual Studio, CMake, Python and Conan), or you already have versions of them or even if you are having build problems, you can use a one of the following Vitual Machines:

• Windows Sandbox - Sandbox can be enabled on Windows 10/11 Pro/Enterprise and can also be installed on Windows Home with a bit of effort. If the build experiences memory errors you will need a configuration file to provide more memory than the default 4GB.
• A virtualisation program - install a VM and and a matching Developer Virtual Machine Image from Microsoft. In most cases VirtualBox will be a good choice (import the Microsoft supplied .ova appliance file but the Visual Studio pre installed in the VM must be uninstalled first to avoid problems).

In both cases you can copy the built files to where they will be run from on you PC file system, possibly by sharing a PC folder with the VM.

Step by Step Instructions

• Ensure you have a PC (or VM) with Windows 10 or 11 installed.
• Make a new folder C:\projects.
• Click on the 'raw' button at the top of the script (below) in this Gist.
• Use the browser Save As (right click) feature to save the script as This PC -> C:\projects\build-audacity.cmd. To avoid it being saved as a text file type the filename in quotes, eg "build-audacity.cmd".
• open a new Windows cmd terminal (Windows + R keys and then type cmd)
• Type cd \projects and enter key.
• Install required tools and build by typing build-audacity.cmd and enter (use -v3.3.3 if requred).
  • Follow the prompts, pressing a key to start each tool's installer (when previous has finished).
  • NB for Visual Studio, make sure you check the "desktop development with C++" workload
  • If you have a non English Windows or Visual Studio then you must also install the English language packs.
• Come back later - it will take at least 10 minutes.
• Audactiy will be launched to test it was built correctly.
  • See the program location printed out at the end of the build so you can run it again.
  • Optionally copy the specified folder to where you want to run Audacity from, optionally renaming it.

(This video by @Renamesk walks you through the process, but the tool installation method has changed.)

If you have any ASIO drivers installed for active connected hardware you should find ASIO is now available in the the Audacity driver selection combo box which probably currently shows 'MME' selected (you may need to show using menu item View -> Toolbars -> Device toolbar).

NB: The Audacity settings and preferences are stored in a folder "Portable Settings" next to the audacity program. If you want to use settings in the user's home directory then delete this folder.

When things go wrong

As with any complex software build there are many moving parts (including Windows itself) and things can sometimes go wrong. Here are some tips if you hit build errors.

If everyhting falls or you just want to shortcut lots of painful debugging then try a Microsoft Windows Virtual machine (VM) as mentioned above.

• make sure you have latest script
• make sure you are in a folder C:\projects in the cmd window
• ensure you are an administrator on your Windows 10 or 11 64 bit PC (ie not a organisational PC)?
• run the script with --cleanall and try again
• uninstall all the tools and installers (Python, cmake, Visual Studio) and then reboot before trying again
  • note having other versions of any of the tools installed may well cause problems - remove them
• ensure you ticked the specified options when installing Visual Studio and Python, reinstall if unsure
• read the error output - clues are often buried in reams of impenetrable text
• disable any Anti Virus - the built-in Microsoft one is usually not a problem
• if your PC is not English make sure you have EN language packs installed for Windows and VS

Thanks

• @diogodh for finding and fixing the bug with conan installations
• The Audacity team for an fantastic audio tool

build-audacity.cmd

@echo off
rem Version: 2.10.0
rem
rem Build audacity with ASIO support on Windows
rem See the following gist for details
rem  https://gist.github.com/SteveALee/da24c2be633340b8791066dd98eb5d0b
rem
rem Options (only one may be specified)
rem
rem --install or none - install tools and build
rem --build - build, no install
rem --noget - build only but don't fetch again from git
rem --getonly - only get the files 
rem --rebuild - cleanall and build
rem --clean - remove built files
rem --cleanall - remove fetched, built files and conan modules
rem --cleaninstall - remove downloaded installation files
rem -vj.m.p version - default is 3.7.0 (using conan 2.3.2) - limited due to dependencies
rem
rem MIT licence
rem steve@fullmeasure.co.uk

TITLE Build Audacity with ASIO

setlocal
rem Clean up arguments
set TARGET=%1
set VERSION=%2
rem substring on empty var fails within parenthesis
if not [%TARGET%] == [] set TARGET_PREFIX=%TARGET:~0,2%
if [%TARGET_PREFIX%] == [-v] (
  set TARGET=%2
  set VERSION=%1
)
if [%TARGET%] == [] set TARGET=--install
if [%VERSION%] == [] (
  set AUDACITY_REL=3.7.0
) else (
  set AUDACITY_REL=%VERSION:~2%
)

set VISUALSTUDIOVER=2022\Community
set VISUALSTUDIOCMAKE=Visual Studio 17 2022
set VSDIR=%ProgramFiles%\Microsoft Visual Studio\%VISUALSTUDIOVER%
set PROJROOT=C:\projects
set AUDACITY=%PROJROOT%\audacity
set AUDACITY_BUILD=%PROJROOT%\audacity-asio
set MAKE_CONFIG=RelWithDebInfo
set EXEDIR=%AUDACITY_BUILD%\%MAKE_CONFIG%
set INSTALLFILEDIR=bin
rem More vaiables set for --install
if [%AUDACITY_REL:~0,3%] == [3.3] (set CONAN_VER=1.59.0) else (set CONAN_VER=2.3.2)
set CMAKE_OPTS=-DAUDACITY_BUILD_LEVEL=2 -Daudacity_has_asio_support=On
if [%AUDACITY_REL:~0,3%] == [3.5] set CMAKE_OPTS=%CMAKE_OPTS% -Daudacity_has_audiocom_upload=On -Daudacity_has_networking=On -Daudacity_has_url_schemes_support=On
if [%AUDACITY_REL:~0,3%] == [3.6] set CMAKE_OPTS=%CMAKE_OPTS% -Daudacity_has_audiocom_upload=On -Daudacity_has_networking=On -Daudacity_has_url_schemes_support=On
if [%AUDACITY_REL:~0,3%] == [3.7] set CMAKE_OPTS=%CMAKE_OPTS% -Daudacity_has_audiocom_upload=On -Daudacity_has_networking=On -Daudacity_has_url_schemes_support=On

rem check projroot exists
if /I not [%~dp0] == [%PROJROOT%\] (
  echo.
  echo Error: This script must be run in %PROJROOT% - see %%PROJROOT%% in file
  echo.
  if not exist %PROJROOT% (
    echo Create %PROJROOT
    goto exit
) else (
  echo cd to %PROJROOT%
  goto exit
)
)

echo.
echo Building Audacity %AUDACITY_REL% 64 bit RelWithDebInfo with ASIO support...
echo.

rem Get tools
rem ANSI escape sequences do not work in if () block so we use goto

set git-url=https://github.com/git-for-windows/git/releases/download/v2.47.0.windows.1/Git-2.47.0-64-bit.exe
set GITPATH=%ProgramFiles%\Git\cmd\
set vs2022-url=https://aka.ms/vs/17/release/vs_community.exe
rem Conan is installed later
if [%CONAN_VER%] == [1.59.0] (
  rem Note Conan 1.59 has dependency issues with python 3.12
  set python-url=https://www.python.org/ftp/python/3.11.0/python-3.11.0-amd64.exe
  set PYTHONPATH=%LOCALAPPDATA%\Programs\Python\Python311\
) else (  
  set python-url=https://www.python.org/ftp/python/3.13.0/python-3.13.0-amd64.exe
  set PYTHONPATH=%LOCALAPPDATA%\Programs\Python\Python313\
)
set PIPPATH=%PYTHONPATH%Scripts\
   
if not [%TARGET%] == [--install] if not [%TARGET%] == [--cleaninstall] goto clean

if [%TARGET%] == [--cleaninstall] echo Cleaning installation files... & rmdir /s/q %INSTALLFILEDIR% 2> :null & goto exit

echo   
echo.
echo Fetching tools..
echo 

mkdir %INSTALLFILEDIR% 2> :null
curl -L %git-url% -o %INSTALLFILEDIR%\g4w.exe
curl -L %vs2022-url% -o %INSTALLFILEDIR%\vs.exe
curl -L %python-url% -o %INSTALLFILEDIR%\python.exe

echo   
echo.
echo Installing tools...
echo.
echo IMPORTANT!! Follow the instructions below for each installer
echo Close each installer when it is done before starting next
echo.
echo Git for Windows
echo Choose the option "Git from the command line..."
pause
%INSTALLFILEDIR%\g4w.exe
echo.
echo Visual Studio: make sure you select the Workload "Desktop development with C++"
echo You can uncheck "Start After installation"
pause
%INSTALLFILEDIR%\vs.exe
echo.
echo Python: make sure you select "Add python.exe to PATH" for future access
pause
%INSTALLFILEDIR%\python.exe
echo.

echo.
echo 
set installing=true
call :clean --rebuild
goto exit

rem subroutine
:cleanall
echo Cleaning source and built files... & rmdir /s/q %AUDACITY% %AUDACITY_BUILD% 2> :null
where /q conan & if ERRORLEVEL 0 echo Cleaning conan cache... & conan remove -c "*" 2>&1 > :null
exit /B

:clean
rem Python is on path, unless in windows sandbox
rem where /q python & if ERRORLEVEL 1 path %PATH%;%PYTHONPATH%
rem where /q pip & if ERRORLEVEL 1 path %PATH%;%PIPPATH%
rem where /q git & if ERRORLEVEL 1 path %PATH%;%GITPATH%
path %PYTHONPATH%;%PIPPATH%;%GITPATH%;%PATH%

if not [%TARGET%] == [--getonly] (
  if /I [%TARGET%] == [--clean] echo Cleaning built files... & rmdir /s/q %AUDACITY_BUILD% 2> :null & goto exit
  if /I [%TARGET%] == [--cleanall] call :cleanall & goto exit
  if /I [%TARGET%] == [--rebuild] call :cleanall
)

rem Launch cmake-gui
rem VS doesn't include this with it's cmake
rem if [%TARGET%]==[--gui] cmake-gui -Daudacity_has_asio_support=On %CMAKE_OPTS% -S %AUDACITY% -B %AUDACITY_BUILD% & goto build

:checktools
rem ensure tools are installed
if not [%TARGET%] == [--noget] (
  where /q git & if ERRORLEVEL 1 echo Git for Windows does not appear to be installed. Re run with "--install" & goto exit /b
)
if not [%TARGET%] == [--getonly] (
  if not exist "%VSDIR%\VC\Auxiliary\Build\vcvars64.bat" echo Visual Studio does not appear to be installed. Re run with "--install" & goto exit /b
  if not defined VisualStudioVersion call "%VSDIR%\VC\Auxiliary\Build\vcvars64.bat"
  where /q python & if ERRORLEVEL 1 echo Python does not appear to be installed. Open a new cmd window or re-run with "--install" & goto exit /b
  where /q conan & if ERRORLEVEL 0 pip show --version conan | findstr /R /C:"Version: %CONAN_VER%" & if ERRORLEVEL 1 echo conan %CONAN_VER% not found & pip uninstall -y -q conan
  where /q conan & if ERRORLEVEL 1 echo installing conan %CONAN_VER% & pip install conan==%CONAN_VER%
)

rem Get source code
:getcode
if /I not [%TARGET%] == [--clean] (
  if /I not [%TARGET%] == [--cleanall] (
    if /I not [%TARGET%] == [--noget] (
      echo Fetching code for Audacity %AUDACITY_REL%...
      echo.
      git clone -b Audacity-%AUDACITY_REL% --depth 1 https://github.com/audacity/audacity/ %AUDACITY%
      if ERRORLEVEL 1 echo Error: cannot fetch the Audacity code. Try the --cleanall or --noget options & goto exit
    )
  )
)

if /I [%TARGET%] == [--getonly] goto exit

if not exist %AUDACITY%\CMakeLists.txt echo The code files appear to be missing from %AUDACITY%. & goto exit

:cmake
cd %AUDACITY%
cmake.exe -G "%VISUALSTUDIOCMAKE%" -DCMAKE_CONFIGURATION_TYPES=%MAKE_CONFIG% %CMAKE_OPTS% -S %AUDACITY% -B %AUDACITY_BUILD% & if ERRORLEVEL 1 echo Error: Cannot create Audacity buildfiles & goto exit

:build
cd %AUDACITY_BUILD%
set msbuild="%VSDIR%\MSBuild\Current\Bin\MsBuild.exe"
%msbuild% ALL_BUILD.vcxproj -p:configuration=%MAKE_CONFIG%
if ERRORLEVEL 1 echo Error: cannot build Audacity & goto exit

rem Settings stored with files rather than home directory
rem See https://manual.audacityteam.org/man/portable_audacity.html
mkdir %EXEDIR%\"Portable Settings"

cd %PROJROOT%

rem All done
echo 
echo.
echo Congratulations!
echo Your new Audacity %AUDACITY_REL% with ASIO support will now launch.
echo The ASIO options will appear if you have ASIO drivers and connected hardware
echo In future just run the audacity.exe. No need to install.
echo.
echo    %EXEDIR%\audacity.exe
echo.
echo Or copy the folder
echo.
echo    %EXEDIR%\
echo.
echo and run the included audacity.exe
echo.
echo Note settings and preferences are stored in "%EXEDIR%\Portable Settings"
echo If you want to use settings in the user's home directory then delete this folder.
echo.
echo 
start %EXEDIR%\audacity.exe
if defined installing exit /B

:exit
cd %PROJROOT%
endlocal

@Sky3RN Compiling is independent of any sound hardware. The issue is how Audacity reacts when it runs. Perhaps having all hardware connected at once is confusing audacity. But you say even with just one. Or all the drivers?

I will double check it works with my ASIO hardware and let you know.

No I don;t speak French - looks good though. My wife is learning :)

@Sky3RN did you try an ASIO DAW or some such to confirm the problem is with Audacity?

@AdamWardUK oh, I see you suggested that too - thanks

@SteveALee

I bumped the Audacity version to 3.3.3 - https://github.com/audacity/audacity/releases/tag/Audacity-3.3.3

Maybe I'm not sure what does "bumped" mean, but it looks like a real Audacity without ASIO.
As I told you before Audacity works fine, it's the version compiled with ASIO who doesn't work. So yeah, the 3.3.3 works, but 3.3.3 with ASIO doesn't work. Same for the 3.3.2.
I don't know if you see what I mean ?

Perhaps having all hardware connected at once is confusing audacity. But you say even with just one. Or all the drivers?

I tried with all hardware connected at the same time, and only with one connected.
Something's blocking and I can't find what and why..

No I don;t speak French - looks good though. My wife is learning :)

👍👍

did you try an ASIO DAW or some such to confirm the problem is with Audacity?

Yep. As far as it's my job, I'm using everyday Mixcraft, sometimes ProTools or Cakewalk or Studio One. Never had any issues with them.

To resume : Audacity works fine but doesn't record in 32 bits float, that's why I'm trying to compile it with ASIO, and when it's compiled it doesn't open and get stuck on the splash screen. Sometimes it asks for the ASIO driver but still gets stuck, and most of the other times I don't have the popup for ASIO selection.
I tried to compile and recompile again and again and again, I don't know how to force this popup to be shown ! It's seem to be a random thing.

@Sky3RN I'm afraid I've run out of ideas for you. I just clean built 3.3.3 and it works fine with my McMillen K-mix ASIO driver. I needed to turn on the Device toolbar to see the ASIO option. It offers all 9 channels. I just didn't try any audio. But you don't get that far. :(

So I can only think it is a Windows issue - unlikely, an Audactity bug, an ASIO driver issue, or a audacity/driver compatibility issue.

In theory compiling twice will have been enough as installed drivers have no influence on the build, only the audacity version number
If you already had visual studio or python installed they may have been issues but I expected a build failure.
Note the --cleanall option deletes all fetched and built files but not the install tools. Try that an uninstalling the tools if you really want to

I can only wish you the best of luck. Sorry.

@SteveALee I understand ! Nop unfortunately !

I used to think it's a Windows issue too, but I tried on 2 different computers. One is my main desktop, the other one is my laptop and they don't have the same setup at all. But they mostly have the same ASIO drivers installed (Zoom, PreSonus, ASIO Link Pro).
I tried with and without any gear connected, same issue : Stuck on the splash screen.

I might think it could be a driver compatibility issue but.. Which one ? I'll have to uninstall all the drivers to find out the messing one ! I'll try.

I use the --cleanall option ! ;-) And I already tried to uninstall the tools and reinstall everything with your script !

Well, thank you so much for your time and your kindness. I guess the only thing to do now is looking deeply on the Internet.

@Sky3RN

I might think it could be a driver compatibility issue but.. Which one ? I'll have to uninstall all the drivers to find out the messing one ! I'll try.

Sadly that is probably your sensible next step. Uninstall all and add one at a time. Don't you just love computers! I'd try only the 32 bit one first as that's a bit unusual. I assume Audacity supports 32 bit OK?

@Sky3RN

And I already tried to uninstall the tools and reinstall everything with your script !

Remember: the script offered here and the post-installed tools are only to compile Audacity!!
They neither affect the runtime of an ASIO build, nor are they necessary on every target machine.

You already wrote, that you checked your built portaudio_x64.dll with an original distribution and vice versa. Another option would be to share (NO - not to publish, only to share for testing) your built DLL with another person and/or get a running version from him or her. That way you could verify if it is really a driver issue with your drivers or a fault at build time.

@Sky3RN thanks @Giermann

I assumed you had no errors in the build and audacity was launched at the end? It seems so from what you say.

if you want to check for any errors / warnings you can run the following to build and send all output the file out.txt. But again I can;t really support you on build errors

build-audacity.cmd --clean > out.txt 2>&1

@SteveALee

Sadly that is probably your sensible next step. Uninstall all and add one at a time. Don't you just love computers! I'd try only the 32 bit one first as that's a bit unusual. I assume Audacity supports 32 bit OK?

I just tried ! I've uninstalled all of my ASIO drivers, recompiled Audacity and.. Still doesn't work.
Yes it normally should support 32 bits float because it's working on Linux natively, didn't have to compile with ASIO.

@Giermann

Another option would be to share (NO - not to publish, only to share for testing) your built DLL with another person and/or get a running version from him or her. That way you could verify if it is really a driver issue with your drivers or a fault at build time.

I will try that !

@SteveALee

I assumed you had no errors in the build and audacity was launched at the end? It seems so from what you say.

I guess there was no error, but everytime I get a "121 avertissements" (I guess in English it's "121 warnings").

Here's the output file : http://pastebin.fr/129044

@SteveALee

It's easier on Linux.. I'm not really familiar with Windows.

Any reason not to stick with Linux? It's been a decent desktop experience for a long time now. Is it availability of other software? Out of Interest which distro?

The reason is more complicated than that ! I use Linux everyday for my "everyday tasks" as I could say. I use Windows only for two things : Recording / Mixing, and video editing. I never use Audacity, I'm not a big fan of this software. But the reason why I'm trying to get this thing fixed is : As a sound engineer and YouTuber talking about sound, a lot of my audience are noobs using Audacity and nothing else. I recently did a video testing the new Zoom UAC-232 which is capable to record in 32 bits float, and I noticed it doesn't work on Audacity. In fact, it works fine with Audacity on Linux, but not with Audacity on Windows. By "doesn't work" I mean it's recognized but doesn't record in 32 bits float in Audacity for Windows 10. That's why I'm trying to know why. And all of my researches led me to this point : Maybe it could come from this ASIO not supported natively on Audacity.

I tried with 2 different ASIO,

So it fails with two different manufacturer's drivers? Might be safe to assume doesn't work with any ASIO drivers? Hmm. I only have a McMillen ASIO driver. Will try to test a new build with it over next few days to ensure something did't go wrong when I bumped the Audacity build version.

Exactly, failed with the PreSonus driver and the Zoom driver. I've seen your script installs Audacity 3.3.2 and now the official release is 3.3.3, maybe it could be the cause ? I don't know. I'm not an expert in dev !

never use the sh*tty ASIO4All.

Good plan. AFAIK it's only for use with ASIO only apps when you have no ASIO drivers. Trouble is many manufacturers got lazy and suggest you use it rather than supplying ASIO drivers. Not multi channel and not latency gains. Sigh. As you say "sh*tty " :)

😁😁😁

The drivers from zoom for their smaller devices have always set the datachunk and native sample rate the computer will be "looking" for from the device. When this doesn't match up (usually DAW software to datachunk size for speed and memory use, Native sample rate to what's on the device itself) you can get all kinds of issues, from sound not showing up to driver not showing up. Also, 32bit windows doesn't exactly have an audio capability for 32bit float natively. I know this because every audio app I've tried in the 32bit versions only goes as high as 24bit. With Linux, you didn't have this problem because linux was 64bit only for a long while before 64bits became the norm for most Windows installations. If you are stuck with a 32bit windows, you are almost always limited to 24bits, 96k, accept with one or two software titles (can't remember which). If you are compiling a 64bit version and still don't get 32bit float (I've had no experience with your device here, so grain of salt), it may be connected to the driver, though I have seen that the device can use 24bit and the system 32 without problems in Adobe Audition. My experience with zoom devices has been that there is a driver interface that you can access to set the sample rate and the data chunk, but the device must be set to the right mode or you will not get audio; or you will get a message in your DAW that it isn't working. My H6 has 2 drivers installed. One is a simpler L\R stereo driver, another is the multitrack driver. If I set the device to Stereo for the connection and the PC for Multitrack, no go. If I set the data chunk wrong, the sound fragments. The sample rate can be higher than the project file, but lower and it'll stutter and possibly flag errors, showing you a thousand popup messages for all the samples you drop.
And the ASIO4ALL driver is not actually an ASIO driver, but an attempt at a clone of it. While I have always had access to the 32bit driver in 32bit Audacity, I haven't tried 64bits.
Here are the possibilities I can see:

1. The DLL you are using is corrupted, replace it with a clean download.
2. The DLL may be flagged as a "Dangerous" file by an AV like Windows Defender, fix that by allowing the file.
3. The script is downloading new versions that mismatch (unlikely, but possible)
4. If the DLL is the result of a Build operation, the build is done but one of the binaries or project files is missing or corrupted.
5. You need to set your path variables on your own, since you may have UAC issues with that (a nasty little gift from Windows 7 that is helpful on occasion).

@htdSoundTech2020 Thank you for your insights! It's a little hard to parse the one big paragraph but some thoughts.

• This gist only automates the Audacity project build so any technical issues using Audacity need to be raised with the project team,
• While the 32 Bit float audio resolution is not directly related to platform bit size, it makes sense 64 bits is required. To be honest older 32 bit platforms are likely to hit all sorts of support issues.
• Yes ASIO4ALL is not ASIO - but this point confuses many due to the inaccurate name ASIO-fake or fauxASIO would be better. It makes normal windows sound appear to be the ASIO interface that Apps that require ASIO drivers demand. You don't get any of the ASIO benefits.

No success. I tried it many time, many ways, with different Audacity version from 3.2.0. I uninstalled the previous Python and CMkake and installed this script's version. No way... I don't know what to do anymore. Always it end up with erros.

Please post the errors here!
I didn't test the latest version yet, but I'm sure we'll find a solution... :)

Thanks @Giermann

@mateusfig I just did a full install and build and got no errors so the basic script is fine. SO perhaps somehting with you PC? There IS a lot of output, especially now conan is used but that's all normal "Noise". In addition to telling us what the errors are...

• What version of Windows?
• try the --cleanall command line option

Thanks @Giermann

@mateusfig I just did a full install and build and got no errors so the basic script is fine. SO perhaps somehting with you PC? There IS a lot of output, especially now conan is used but that's all normal "Noise". In addition to telling us what the errors are...

• What version of Windows?
• try the --cleanall command line option

Thanks for your feedback.

I use Windows 10 Pro (19045.3448).

I tried --cleanall a few times.

I will try build once again and I will try post the erros in the end of the proccess.

Best of luck - do try grabbing a fresh copy of the script - just in case. I should put a version number at the top

@SteveALee

I just tried once again with no success, using 2.0.1 scriptt version.

I appended the full output from cmd: https://pastebin.com/z69hRC8x

@mateusfig @Giermann O wow,

so it seems to be barfing when trying to link to create a libsndfile conan component

That in turn maybe caused by this:

C:\Program Files\Microsoft Visual Studio\2022\Community\MSBuild\Microsoft\VC\v170\Microsoft.CppCommon.targets(249,5): warning MSB8065: Custom build for item "C:\Users\mmachado.conan\data\libsndfile\1.0.31__\build\899d2c53f1b9e4a7deb461e3cf1716f2d4fd697d\build\CMakeFiles\bf18e4cabeda36cd82ee3e51ae56b6cc\sndfile.def.rule" succeeded, but specified output "c:\users\mmachado.conan\data\libsndfile\1.0.31__\build\899d2c53f1b9e4a7deb461e3cf1716f2d4fd697d\build\src\sndfile.def" has not been created. This may cause incremental build to work incorrectly. [C:\Users\mmachado.conan\data\libsndfile\1.0.31__\build\899d2c53f1b9e4a7deb461e3cf1716f2d4fd697d\build\sndfile.vcxproj]

There were a LOT of warnings for that file which to me is a code smell but might have been expected.

I noticed some output text "Versão do MSBuild 17.7.2+d6990bcfa para .NET Framework" and previously a French native had problems which caused us to mention in the Gist instructions that English language packs might be required for both Windows and Visual Studio. The errors don't indicate language filename problems, but perhaps something to do with incremental build (why?)

Otherwise I'll have to pass over the @Giermann

When I have time I'll compare to me logs

@SteveALee ,

Loads of errors...

My native language is portuguese. My Visual Studio has english language package, but my Windows 10 doesn't. I will try installing english language pack on Windows 10.

That's the CMakeError.log content:

https://pastebin.com/CDFDwjev

@mateusfig is that after installing the Windows EN language pack? It seems it cannot locate the [we function in MSVC (the C compiler included in Visual Studio)

As we have no idea what kind of mess Microsoft might have made of language dependencies (if any) I I would uninstall/reinstall everything and be sure to run --cleanall. Sorry for this pain.

@mateusfig
First of all, markdown language seems not to be the best choice to paste large text files. Maybe you should better use another service, for example pastebin.com and only copy the link to the files here.
If you are able to do that, it would be much easier to follow other comments if you paste your files there and then edit your comments - thank you very much!

But now to your issue: I just started a fresh run of the provided script on a (nearly) clean install of Windows (German) and the build succeeded without errors.
Then I compared the output and also identified the already mentioned warning "MSB8065" to be the main difference. For some reason, it is not creating the "sndfile.def" in libsndfile which finally leads to error "LNK1104".

A Google search returned a similiar issue (reported at StackOverflow) when the manually set date of a computer was before the creation of the source files. So I did some tricks to verify that, but was only able to verify it with a date after 12th of September, because git refuses to connect to sites with invalid SSL certificates.
But even this completed successfully (all runs with 121 warnings).
So, I don't know how to continue from here...

@Giermann Great work. Thanks for confirming it can work! I agree with your error detection - that was the first I saw.

As far as I recall git doesn't preserve file timestamps on clone/fetch (a right pain). So as long as a --cleanall or otherwise deleting the source was was done , forcing the files to be re fetched they'd have to be dated before current clock time - unless there is a really weird clock thing happening. Perhaps if localisation of time format is different between Windows GUI and command line - clutching at a straw there. I'm also stuck I'm afraid.

@mateusfig is that after installing the Windows EN language pack? It seems it cannot locate the [we function in MSVC (the C compiler included in Visual Studio)

As we have no idea what kind of mess Microsoft might have made of language dependencies (if any) I I would uninstall/reinstall everything and be sure to run --cleanall. Sorry for this pain.

I don't have installed EN language pack still. I will try it. I guess also this is the problem.

@mateusfig First of all, markdown language seems not to be the best choice to paste large text files. Maybe you should better use another service, for example pastebin.com and only copy the link to the files here. If you are able to do that, it would be much easier to follow other comments if you paste your files there and then edit your comments - thank you very much!

But now to your issue: I just started a fresh run of the provided script on a (nearly) clean install of Windows (German) and the build succeeded without errors. Then I compared the output and also identified the already mentioned warning "MSB8065" to be the main difference. For some reason, it is not creating the "sndfile.def" in libsndfile which finally leads to error "LNK1104".

A Google search returned a similiar issue (reported at StackOverflow) when the manually set date of a computer was before the creation of the source files. So I did some tricks to verify that, but was only able to verify it with a date after 12th of September, because git refuses to connect to sites with invalid SSL certificates. But even this completed successfully (all runs with 121 warnings). So, I don't know how to continue from here...

I'm sorry for my long text post. I just corrected this with pastbin.com

My issue is kind of weird. I will try the build on another computer (no EN language package also) and see what I 'll get.

@mateusfig is that after installing the Windows EN language pack? It seems it cannot locate the [we function in MSVC (the C compiler included in Visual Studio)
As we have no idea what kind of mess Microsoft might have made of language dependencies (if any) I I would uninstall/reinstall everything and be sure to run --cleanall. Sorry for this pain.

I don't have installed EN language pack still. I will try it. I guess also this is the problem.

I installed EN language pack and got same issue.

Did you already try on another computer?
Can you also try to change line 137 in the script and modify "-Daudacity_has_asio_support=On" to "-Daudacity_has_asio_support=Off"?
I'm pretty sure, the problem is related to the build in general, not ASIO specific.

If this also fails, it would be time to open an issue to get support from the Audacity team:
https://github.com/audacity/audacity/issues

Another idea: the issue leading to MSB8065 seems to be compiler dependent.
You could try to use another version of Visual Studio, i.e. 2019 instead of 2022.

To do so, uninstall all components (Python, cmake, Visual Studio and its installer), reboot and try again with a fork of Steves script, which I modified to choose the VS version:
https://gist.github.com/Giermann/c3f88ee2a147f9a688a2ca76e1334a54
Set VISUALSTUDIO_REL in line 34 to either 2019 or 2017 and then start from scratch with "--install" and so on...

I updated to Audacity 3.4.0 and switched to using the "cmake" that comes with Visual Studio. This means the cmake-gui option is no longer available.

I also cleaned up the flow so the --install option no longer required a new cmd window to be opened .