-
Disregard the original steam shortcut and only use the batch scripts below to launch steam
-
There is a slight CPU utilization penalty which can be circumvented by suspending the problematic thread
- See this comment
steam-no-browser.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe" +open steam://open/minigameslist -vgui
:: only continue if steamwebhelper is running in case steam is updating
:query_steamwebhelper
tasklist | findstr /i "steamwebhelper.exe" || goto :query_steamwebhelper
:: allow a few seconds for steam to initialize/login
timeout /t 5 /nobreak
:: rename binary and kill the process
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exe"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exee"
)
)
taskkill /f /im "steamwebhelper.exe"
steam-normal.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe"
Guys original "steam-no-browser.bat" still works, you just have to increase
timeout /t 5 /nobreak
to something liketimeout /t 30 /nobreak
With the current 5 seconds steamwebhelper process gets killed and renamed too quickly and you get the "steamwebhelper is not responding" error. Increasing timeout will allow steam to properly initialize/login and you have a few seconds left to launch the game you want to play. After you're done playing and want to launch different game, you will have to kill steam.exe process(or right click tray icon and wait for error to appear, then select close steam) and launch it again with steam-no-browser.bat and start your game.
You don't even have to run "steam-normal.bat" anymore, as steam automatically restores steamwebhelper.exe on each launch if it detects that's missing(renamed).