-
Disregard the original steam shortcut and only use the batch scripts below to launch steam
-
There is a slight CPU utilization penalty which can be circumvented by suspending the problematic thread
- See this comment
steam-no-browser.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe" +open steam://open/minigameslist -vgui
:: only continue if steamwebhelper is running in case steam is updating
:query_steamwebhelper
tasklist | findstr /i "steamwebhelper.exe" || goto :query_steamwebhelper
:: allow a few seconds for steam to initialize/login
timeout /t 5 /nobreak
:: rename binary and kill the process
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exe"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exee"
)
)
taskkill /f /im "steamwebhelper.exe"
steam-normal.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe"
alternative steamwebhelper_min.bat
What it does:
mainly
--single-process
and--enable-low-end-device-mode
but doing it this way it works when steam asks for self-restarting to apply an update--disable-background-networking
and it generally helps, but you can fully disable networking for steamwebhelper (via fake localhost proxy) with the OFFLINE variable at the top of the script (then Friends, Store won't launch)-no-browser
will surely be missed, there's no easy way to replicate it now without multiple downsides to killing and physically deleting the files on disk or forcefully suspending threads & etc.My alternative is a bit more graceful at it, and managed to reduce idle ram usage to under 100MB, but it's certainly not a killer.