Minimal dapper in F#

Dapper.fs

module DapperFSharp =
    open System.Data.SqlClient
    open System.Dynamic
    open System.Collections.Generic
    open Dapper

    let dapperQuery<'Result> (query:string) (connection:SqlConnection) =
        connection.Query<'Result>(query)
    
    let dapperParametrizedQuery<'Result> (query:string) (param:obj) (connection:SqlConnection) : 'Result seq =
        connection.Query<'Result>(query, param)
    
    let dapperMapParametrizedQuery<'Result> (query:string) (param : Map<string,_>) (connection:SqlConnection) : 'Result seq =
        let expando = ExpandoObject()
        let expandoDictionary = expando :> IDictionary<string,obj>
        for paramValue in param do
            expandoDictionary.Add(paramValue.Key, paramValue.Value :> obj)
    
        connection |> dapperParametrizedQuery query expando

Sample.fsx

type User = { UserId:string }

let getUsers connection =
    connection
    |> dapperQuery<User> "SELECT UserID From tbUser"
    
let getUser userId connection =
    connection
    |> dapperMapParametrizedQuery<User> "SELECT UserID From tbUser WHERE UserId = @UserId" (Map ["UserId", userId])
    |> Seq.head

type UserSelectArgs = { SelectedUserId:string}

let getUser' userId connection =
    connection
    |> dapperParametrizedQuery<User> "SELECT UserID From tbUser WHERE UserId = @SelectedUserId" {SelectedUserId=userId}
    |> Seq.head

I found this via a google search ;)

Nice!

great!

Can anyone comment on how this compares to FsSql? -> https://github.com/mausch/FsSql
Seems similar at a glance.

Awesome

This looks great! I was wondering whether you could help me out here. When I run this in and try to print out something like the "getUsers" over my data all I get is<fun:users@187>. I've tried iterating with Seq.iter and Seq.map for individuals printing. I even had to cast the items with Seq.cast and I'm getting errors that my expression isn't finished even when I call something like Seq.head on the last pipe. What am I not understanding?

incomplete, created these two files in f# and imported Dapper in PM and red squiggles all over!

I found this example very helpful but I needed one more thing to get it all working with Dotnet Core 2.1.3: the result types have to be annotated with [<CLIMutable>] in order to give the record a default constructor with property getters/setters.

Also, I noticed that passing the Map directly in dapperMapParametrizedQuery works fine without having to create an Expando. That function turns into a one-liner. Not sure if this is specific to the 2.1.3.

@ovatsug25, it sounds like you're only partially applying the function. Are you sure you passed all the arguments, like the connection argument as well?

What do you think about this?
https://github.com/AlexTroshkin/fsharp-dapper
https://www.nuget.org/packages/FSharp.Data.Dapper

It would be nice if the sample script included an example of how to run the functions (including a sample connection string).

This looks useful. I'm trying to port a C# Dapper library using the Unit of Work pattern which is how I ended up here. What's missing (for me) is a way to wrap this up with transactions.

Definitely would be a plus to add the "chrome" around these snippets. They're very helpful. New users can add

open System.Data.SqlClient
open Dapper
open Npgsql

let connString = "Host=localhost;Database=exampleDB;Username=postgres;Password=example"
let connection = new NpgsqlConnection(connString)
connection.Open()

Note: You'll also need to install Npgsql: dotnet add package Npgsql --version 3.2.7 if you're using Postgres, like I am.

Many thanks @vbfox & @nobleach, the script works and saved me hours of frustration!