-
Disregard the original steam shortcut and only use the batch scripts below to launch steam
-
There is a slight CPU utilization penalty which can be circumvented by suspending the problematic thread
- See this comment
steam-no-browser.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe" +open steam://open/minigameslist -vgui
:: only continue if steamwebhelper is running in case steam is updating
:query_steamwebhelper
tasklist | findstr /i "steamwebhelper.exe" || goto :query_steamwebhelper
:: allow a few seconds for steam to initialize/login
timeout /t 5 /nobreak
:: rename binary and kill the process
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exe"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exee"
)
)
taskkill /f /im "steamwebhelper.exe"
steam-normal.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe"
https://steamcommunity.com/groups/SteamClientBeta/discussions/3/3710433479207750727/#c3763355849151540150
or my extra notes: https://steamcommunity.com/discussions/forum/0/3758852249527312123/
Then you have to decide if you want a separate non-updating client or to replace your Steam. In the former case, you also have to decide if you want to share the Steam libraries or not. I've had some issues with game update recognition when appinfo.vdf/packageinfo.vdf were not shared between the two installs – or at least that's my guess.