-
Disregard the original steam shortcut and only use the batch scripts below to launch steam
-
There is a slight CPU utilization penalty which can be circumvented by suspending the problematic thread
- See this comment
steam-no-browser.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe" +open steam://open/minigameslist -vgui
:: only continue if steamwebhelper is running in case steam is updating
:query_steamwebhelper
tasklist | findstr /i "steamwebhelper.exe" || goto :query_steamwebhelper
:: allow a few seconds for steam to initialize/login
timeout /t 5 /nobreak
:: rename binary and kill the process
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exe"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exee"
)
)
taskkill /f /im "steamwebhelper.exe"
steam-normal.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe"
@refriedfood
If you need the friends list to join another player, you can use Steam chat in the web browser on games that can join others (using the 'Join Game' chat dropdown option or by accepting an invite in chat) from out of game. If the game cannot join your friend using launch parameters, this doesn't help.
If you need the friends list to invite someone to your game, use 2022 Steam with -no-browser since you still get the old chat there. That also gets you the old chat in the overlay.