-
Disregard the original steam shortcut and only use the batch scripts below to launch steam
-
There is a slight CPU utilization penalty which can be circumvented by suspending the problematic thread
- See this comment
steam-no-browser.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe" +open steam://open/minigameslist -vgui
:: only continue if steamwebhelper is running in case steam is updating
:query_steamwebhelper
tasklist | findstr /i "steamwebhelper.exe" || goto :query_steamwebhelper
:: allow a few seconds for steam to initialize/login
timeout /t 5 /nobreak
:: rename binary and kill the process
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exe"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exee"
)
)
taskkill /f /im "steamwebhelper.exe"
steam-normal.bat:
@echo off
setlocal EnableDelayedExpansion
set "steam_path=C:\Program Files (x86)\Steam"
:: kill steam if is running
tasklist | findstr /i "steam.exe" && taskkill /f /im "steam.exe"
:: rename binary back to .exe as steam requires it to initialize
for %%a in ("cef.win7", "cef.win7x64") do (
set "bin=!steam_path!\bin\cef\%%~a\steamwebhelper.exee"
if exist "!bin!" (
ren "!bin!" "steamwebhelper.exe"
)
)
:: open steam
start "" "!steam_path!\steam.exe"
I just hadn't launched a game in all that time.
Now that I've launched a game, the helpers have returned, and my Steam client has returned to normal.
Resource Manager didn't show them either, prior to launching.
Interestingly, repeating the process works just fine, even when the game overlay active, although I had to terminate the instance of the game overlay (which then relaunched with no webhelpers), and it all seems to be fine again.
Relaunched the game, no webhelpers spawned, however the initial GameOverlay executable causes the main steam client to hang, ending the overlay task has it restart and work as expected, minus any web based functions.
Organised by name: